Version bump, fixes systemd linking (#502530)

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 71 insertions, 1 deletions

diff --git a/net-nds/ypbind/ChangeLog b/net-nds/ypbind/ChangeLog
index 77d1d5f21cd3..5ba0ff533605 100644
--- a/net-nds/ypbind/ChangeLog
+++ b/net-nds/ypbind/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nds/ypbind
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ChangeLog,v 1.86 2014/06/26 12:45:26 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ChangeLog,v 1.87 2014/09/24 11:21:21 pacho Exp $
+
+*ypbind-1.37.2 (24 Sep 2014)
+
+  24 Sep 2014; Pacho Ramos <pacho@gentoo.org> +ypbind-1.37.2.ebuild:
+  Version bump, fixes systemd linking (#502530)
 
   26 Jun 2014; Michael Palimaka <kensington@gentoo.org>
   -files/ypbind-1.31-man-port.patch, -ypbind-1.33.ebuild:
diff --git a/net-nds/ypbind/ypbind-1.37.2.ebuild b/net-nds/ypbind/ypbind-1.37.2.ebuild
new file mode 100644
index 000000000000..733938107e58
--- /dev/null
+++ b/net-nds/ypbind/ypbind-1.37.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ypbind-1.37.2.ebuild,v 1.1 2014/09/24 11:21:21 pacho Exp $
+
+EAPI=5
+inherit readme.gentoo systemd
+
+MY_P=${PN}-mt-${PV}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Multithreaded NIS bind service (ypbind-mt)"
+HOMEPAGE="http://www.linux-nis.org/nis/ypbind-mt/index.html"
+SRC_URI="http://www.linux-nis.org/download/ypbind-mt/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug dbus nls slp systemd"
+
+RDEPEND="
+	debug? ( dev-libs/dmalloc )
+	dbus? ( dev-libs/dbus-glib )
+	slp? ( net-libs/openslp )
+	systemd? (
+		net-nds/rpcbind
+		>=net-nds/yp-tools-2.12-r1
+		sys-apps/systemd )
+	!systemd? (
+		net-nds/yp-tools
+		|| ( net-nds/portmap net-nds/rpcbind ) )
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+DOC_CONTENTS="
+	If you are using dhcpcd, be sure to add the -Y option to
+	dhcpcd_eth0 (or eth1, etc.) to keep dhcpcd from clobbering
+	/etc/yp.conf.
+"
+
+src_prepare() {
+	! use systemd && export ac_cv_header_systemd_sd_daemon_h=no
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable slp) \
+		$(use_with debug dmalloc) \
+		$(use_enable dbus dbus-nm)
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	newins etc/yp.conf yp.conf.example
+
+	newconfd "${FILESDIR}/ypbind.confd-r1" ypbind
+	newinitd "${FILESDIR}/ypbind.initd" ypbind
+	use systemd && systemd_dounit "${FILESDIR}/ypbind.service"
+
+	readme.gentoo_create_doc
+}