Version bump, update ebuild for ocsync merge, fixes bug #501372

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

3 files changed, 73 insertions, 1 deletions

diff --git a/net-misc/owncloud-client/ChangeLog b/net-misc/owncloud-client/ChangeLog
index 80d1ccaeba8b..8430d4d74d90 100644
--- a/net-misc/owncloud-client/ChangeLog
+++ b/net-misc/owncloud-client/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/owncloud-client
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.2 2014/02/07 14:06:20 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.3 2014/02/24 15:43:10 voyageur Exp $
+
+*owncloud-client-1.5.1 (24 Feb 2014)
+
+  24 Feb 2014; Bernard Cafarelli <voyageur@gentoo.org>
+  +owncloud-client-1.5.1.ebuild, metadata.xml:
+  Version bump, update ebuild for ocsync merge, fixes bug #501372
 
   07 Feb 2014; Bernard Cafarelli <voyageur@gentoo.org>
   owncloud-client-1.5.0.ebuild:
diff --git a/net-misc/owncloud-client/metadata.xml b/net-misc/owncloud-client/metadata.xml
index ea02039c8d10..f713f2a74b47 100644
--- a/net-misc/owncloud-client/metadata.xml
+++ b/net-misc/owncloud-client/metadata.xml
@@ -5,4 +5,7 @@
 		<email>voyageur@gentoo.org</email>
 		<name>Bernard Cafarelli</name>
 	</maintainer>
+	<use>
+		<flag name="sftp">Enable sftp transfer support via <pkg>net-libs/libssh</pkg></flag>
+	</use>
 </pkgmetadata>
diff --git a/net-misc/owncloud-client/owncloud-client-1.5.1.ebuild b/net-misc/owncloud-client/owncloud-client-1.5.1.ebuild
new file mode 100644
index 000000000000..6deefd0ae3ed
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-1.5.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.5.1.ebuild,v 1.1 2014/02/24 15:43:10 voyageur Exp $
+
+EAPI=5
+
+inherit cmake-utils
+
+MY_P="mirall-${PV/_/}"
+
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="http://owncloud.org/"
+SRC_URI="http://download.owncloud.com/desktop/stable/${MY_P}.tar.bz2"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc samba +sftp test"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain
+	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
+	dev-qt/qtgui:4
+	dev-qt/qttest:4
+	dev-qt/qtwebkit:4
+	net-libs/neon[ssl]
+	sys-fs/inotify-tools
+	virtual/libiconv
+	samba? ( >=net-fs/samba-3.5 )
+	sftp? ( >=net-libs/libssh-0.5 )
+	!net-misc/ocsync"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	doc? (
+		dev-python/sphinx
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	test? ( dev-util/cmocka )"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DWITH_ICONV=ON
+		$(cmake-utils_use_with doc DOC)
+		$(cmake-utils_use test UNIT_TESTING)
+		$(cmake-utils_use_find_package samba Libsmbclient)
+		$(cmake-utils_use_find_package sftp LibSSH)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	# 1 test needs an existing ${HOME}/.config directory
+	mkdir "${T}"/.config
+	export HOME="${T}"
+	cmake-utils_src_test
+}