eapi2ify, check boost python use dep, add doc useflag

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 72 insertions, 1 deletions

diff --git a/net-libs/rb_libtorrent/ChangeLog b/net-libs/rb_libtorrent/ChangeLog
index 965048fdeb2f..e7eb5a805439 100644
--- a/net-libs/rb_libtorrent/ChangeLog
+++ b/net-libs/rb_libtorrent/ChangeLog
@@ -1,6 +1,17 @@
 # ChangeLog for net-libs/rb_libtorrent
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.59 2009/06/28 00:02:56 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.60 2009/06/28 14:50:42 yngwin Exp $
+
+*rb_libtorrent-0.14.4-r1 (28 Jun 2009)
+
+  28 Jun 2009; Ben de Groot <yngwin@gentoo.org>
+  +rb_libtorrent-0.14.4-r1.ebuild:
+  Update ebuild for version 0.14.4:
+  - migrate to eapi-2
+  - add doc useflag to install HTML documentation
+  - check for python-enabled boost if USE=python (bug 270608)
+  - add switch for verbose logging if USE=debug (todo from previous
+  revision)
 
 *rb_libtorrent-0.13-r1 (27 Jun 2009)
 
diff --git a/net-libs/rb_libtorrent/rb_libtorrent-0.14.4-r1.ebuild b/net-libs/rb_libtorrent/rb_libtorrent-0.14.4-r1.ebuild
new file mode 100644
index 000000000000..e02dca2b1065
--- /dev/null
+++ b/net-libs/rb_libtorrent/rb_libtorrent-0.14.4-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.14.4-r1.ebuild,v 1.1 2009/06/28 14:50:42 yngwin Exp $
+
+EAPI="2"
+inherit eutils flag-o-matic
+
+MY_P=${P/rb_/}
+MY_P=${MY_P/torrent/torrent-rasterbar}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
+HOMEPAGE="http://www.rasterbar.com/products/libtorrent/"
+SRC_URI="mirror://sourceforge/libtorrent/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="debug doc examples python test"
+
+DEPEND="!net-libs/libtorrent
+	|| ( >=dev-libs/boost-1.35
+		( ~dev-libs/boost-1.34.1 dev-cpp/asio ) )
+	python? ( || ( >=dev-libs/boost-1.35.0-r5[python]
+		=dev-libs/boost-1.35.0-r2 ) )
+	sys-libs/zlib"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	append-ldflags -pthread
+
+	#use multi-threading versions of boost libs
+	local BOOST_LIBS="--with-boost-system=boost_system-mt \
+		--with-boost-asio=boost_system-mt \
+		--with-boost-filesystem=boost_filesystem-mt \
+		--with-boost-thread=boost_thread-mt \
+		--with-boost-regex=boost_regex-mt \
+		--with-boost-python=boost_python-mt \
+		--with-boost-program_options=boost_program_options-mt"
+
+	local LOGGING
+	use debug && LOGGING="--with-logging=verbose"
+
+	econf $(use_enable debug) \
+		$(use_enable test tests) \
+		$(use_enable examples) \
+		$(use_enable python python-binding) \
+		--with-zlib=system \
+		--with-asio=system \
+		${LOGGING} \
+		${BOOST_LIBS}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die 'emake install failed'
+	dodoc ChangeLog AUTHORS NEWS README || die 'dodoc failed'
+	if use doc ; then
+		dohtml docs/* || die "Could not install HTML documentation"
+	fi
+}