Version bump (bug #473726). Refactor ebuild to be much less verbose, use usex rather than myconf. Add avs USE flag. Drop 0.0.20110426 since it uses an old EAPI.

(Portage version: 2.1.12.5/cvs/Linux x86_64, signed Manifest commit with key 5C350883)

5 files changed, 127 insertions, 109 deletions

diff --git a/media-video/x264-encoder/ChangeLog b/media-video/x264-encoder/ChangeLog
index d4b6f71669a5..773976381cd7 100644
--- a/media-video/x264-encoder/ChangeLog
+++ b/media-video/x264-encoder/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for media-video/x264-encoder
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.69 2013/01/17 10:23:12 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.70 2013/06/18 23:02:45 chutzpah Exp $
+
+*x264-encoder-0.0.20130506 (18 Jun 2013)
+
+  18 Jun 2013; Patrick McLean <chutz@gentoo.org>
+  -x264-encoder-0.0.20110426.ebuild, +x264-encoder-0.0.20130506.ebuild,
+  x264-encoder-9999.ebuild, metadata.xml:
+  Version bump (bug #473726). Refactor ebuild to be much less verbose, use usex
+  rather than myconf. Add avs USE flag. Drop 0.0.20110426 since it uses an old
+  EAPI.
 
   17 Jan 2013; Luca Barbato <lu_zero@gentoo.org>
   x264-encoder-0.0.20120707.ebuild:
diff --git a/media-video/x264-encoder/metadata.xml b/media-video/x264-encoder/metadata.xml
index de9b645c7fb3..83ba4ce14f4d 100644
--- a/media-video/x264-encoder/metadata.xml
+++ b/media-video/x264-encoder/metadata.xml
@@ -6,8 +6,9 @@
     <email>media-video@gentoo.org</email>
   </maintainer>
   <use>
-      <flag name="10bit">Set output bit depth to 10</flag>
-      <flag name="interlaced">Enable interlaced encoding support, this can decrease encoding speed by up to 2%</flag>
-      <flag name="ffmpegsource">Enable ffmpegsource aka ffms support, disables lavf</flag>
+    <flag name="10bit">Set output bit depth to 10</flag>
+    <flag name="avs">enable AvxSynth support in the AviSynth input module</flag>
+    <flag name="ffmpegsource">Enable ffmpegsource aka ffms support, disables lavf</flag>
+    <flag name="interlaced">Enable interlaced encoding support, this can decrease encoding speed by up to 2%</flag>
   </use>
 </pkgmetadata>
diff --git a/media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild b/media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild
deleted file mode 100644
index 2483ee288d90..000000000000
--- a/media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild,v 1.6 2012/05/05 08:58:56 jdhore Exp $
-
-EAPI=2
-inherit eutils multilib toolchain-funcs versionator
-
-MY_P=x264-snapshot-$(get_version_component_range 3)-2245
-
-DESCRIPTION="A free commandline encoder for X264/AVC streams"
-HOMEPAGE="http://www.videolan.org/developers/x264.html"
-SRC_URI="http://ftp.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="alpha amd64 ppc ppc64 sparc x86 ~x86-fbsd"
-IUSE="debug ffmpeg +mp4 +threads"
-
-RDEPEND="mp4? ( >=media-video/gpac-0.4.1_pre20060122 )
-	~media-libs/x264-${PV}
-	ffmpeg? ( virtual/ffmpeg )"
-DEPEND="${RDEPEND}
-	amd64? ( >=dev-lang/yasm-0.6.2 )
-	x86? ( || ( >=dev-lang/yasm-0.6.2 dev-lang/nasm )
-		!<dev-lang/yasm-0.6.2 )
-	x86-fbsd? ( >=dev-lang/yasm-0.6.2 )
-	virtual/pkgconfig"
-
-S="${WORKDIR}/${MY_P}"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-nostrip.patch \
-		"${FILESDIR}"/${PN}-nolib-20110425.patch
-}
-
-src_configure() {
-	tc-export CC
-
-	local myconf=""
-	use debug && myconf="${myconf} --enable-debug"
-
-	./configure \
-		--prefix=/usr \
-		--libdir=/usr/$(get_libdir) \
-		--disable-avs \
-		$(use_enable ffmpeg lavf) \
-		$(use_enable ffmpeg swscale) \
-		$(use_enable mp4 gpac) \
-		$(use_enable threads thread) \
-		--extra-asflags="${ASFLAGS}" \
-		--extra-cflags="${CFLAGS}" \
-		--extra-ldflags="${LDFLAGS}" \
-		--host="${CHOST}" \
-		${myconf} \
-		|| die
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die
-}
diff --git a/media-video/x264-encoder/x264-encoder-0.0.20130506.ebuild b/media-video/x264-encoder/x264-encoder-0.0.20130506.ebuild
new file mode 100644
index 000000000000..89bd45571fa3
--- /dev/null
+++ b/media-video/x264-encoder/x264-encoder-0.0.20130506.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20130506.ebuild,v 1.1 2013/06/18 23:02:45 chutzpah Exp $
+
+EAPI=5
+
+inherit flag-o-matic multilib toolchain-funcs
+
+DESCRIPTION="A free commandline encoder for X264/AVC streams"
+HOMEPAGE="http://www.videolan.org/developers/x264.html"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-2
+	EGIT_BRANCH=stable
+	EGIT_REPO_URI="git://git.videolan.org/x264.git"
+	SRC_URI=""
+else
+	inherit versionator
+	MY_P="x264-snapshot-$(get_version_component_range 3)-2245"
+	SRC_URI="http://download.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="10bit avs custom-cflags debug ffmpeg ffmpegsource +interlaced mp4 +threads"
+
+REQUIRED_USE="ffmpegsource? ( ffmpeg )"
+
+RDEPEND="ffmpeg? ( virtual/ffmpeg )
+	~media-libs/x264-${PV}[10bit=,debug=,interlaced=,threads=]
+	ffmpegsource? ( media-libs/ffmpegsource )
+	mp4? ( >=media-video/gpac-0.4.1_pre20060122 )"
+
+ASM_DEP=">=dev-lang/yasm-1.2.0"
+DEPEND="${RDEPEND}
+	amd64? ( ${ASM_DEP} )
+	x86? ( ${ASM_DEP} )
+	x86-fbsd? ( ${ASM_DEP} )
+	virtual/pkgconfig"
+
+src_configure() {
+	tc-export CC
+
+	# let upstream pick the optimization level by default
+	use custom-cflags || filter-flags -O?
+
+	./configure \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--system-libx264 \
+		--host="${CHOST}" \
+		$(usex 10bit "--bit-depth=10" "") \
+		$(usex avs "" "--disable-avs") \
+		$(usex debug "--enable-debug" "") \
+		$(usex ffmpeg "" "--disable-lavf --disable-swscale") \
+		$(usex ffmpegsource "" "--disable-ffms") \
+		$(usex interlaced "" "--disable-interlaced") \
+		$(usex mp4 "" "--disable-gpac") \
+		$(usex threads "" "--disable-thread") || die
+
+	# this is a nasty workaround for bug #376925 for x264 that also applies
+	# here, needed because as upstream doesn't like us fiddling with their CFLAGS
+	if use custom-cflags; then
+		local cflags
+		cflags="$(grep "^CFLAGS=" config.mak | sed 's/CFLAGS=//')"
+		cflags="${cflags//$(get-flag O)/}"
+		cflags="${cflags//-O? /$(get-flag O) }"
+		cflags="${cflags//-g /}"
+		sed -i "s:^CFLAGS=.*:CFLAGS=${cflags//:/\\:}:" config.mak
+	fi
+}
diff --git a/media-video/x264-encoder/x264-encoder-9999.ebuild b/media-video/x264-encoder/x264-encoder-9999.ebuild
index d6db1c3fe6e3..ad6927e1b135 100644
--- a/media-video/x264-encoder/x264-encoder-9999.ebuild
+++ b/media-video/x264-encoder/x264-encoder-9999.ebuild
@@ -1,76 +1,72 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/x264-encoder-9999.ebuild,v 1.4 2012/05/05 08:58:56 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/x264-encoder-9999.ebuild,v 1.5 2013/06/18 23:02:45 chutzpah Exp $
 
-EAPI=4
+EAPI=5
 
-if [ "${PV#9999}" != "${PV}" ] ; then
-	V_ECLASS="git-2"
-else
-	V_ECLASS="versionator"
-fi
+inherit flag-o-matic multilib toolchain-funcs
 
-inherit multilib toolchain-funcs ${V_ECLASS}
-
-if [ "${PV#9999}" = "${PV}" ] ; then
-	MY_P="x264-snapshot-$(get_version_component_range 3)-2245-stable"
-fi
 DESCRIPTION="A free commandline encoder for X264/AVC streams"
 HOMEPAGE="http://www.videolan.org/developers/x264.html"
-if [ "${PV#9999}" != "${PV}" ] ; then
+if [[ ${PV} == 9999 ]]; then
+	inherit git-2
+	EGIT_BRANCH=stable
 	EGIT_REPO_URI="git://git.videolan.org/x264.git"
 	SRC_URI=""
 else
+	inherit versionator
+	MY_P="x264-snapshot-$(get_version_component_range 3)-2245"
 	SRC_URI="http://download.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+	S="${WORKDIR}/${MY_P}"
 fi
 
 LICENSE="GPL-2"
 SLOT="0"
-if [ "${PV#9999}" != "${PV}" ] ; then
-	KEYWORDS=""
-else
-	KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-fi
-IUSE="debug ffmpeg ffmpegsource mp4 +threads"
+IUSE="10bit avs custom-cflags debug ffmpeg ffmpegsource +interlaced mp4 +threads"
 
 REQUIRED_USE="ffmpegsource? ( ffmpeg )"
 
-RDEPEND="
-	ffmpeg? ( virtual/ffmpeg )
+RDEPEND="ffmpeg? ( virtual/ffmpeg )
+	~media-libs/x264-${PV}[10bit=,debug=,interlaced=,threads=]
 	ffmpegsource? ( media-libs/ffmpegsource )
-	mp4? ( >=media-video/gpac-0.4.1_pre20060122 )
-	~media-libs/x264-${PV}
-"
-ASM_DEP=">=dev-lang/yasm-0.6.2"
+	mp4? ( >=media-video/gpac-0.4.1_pre20060122 )"
+
+ASM_DEP=">=dev-lang/yasm-1.2.0"
 DEPEND="${RDEPEND}
 	amd64? ( ${ASM_DEP} )
-	x86? ( || ( ${ASM_DEP} dev-lang/nasm )
-		!<dev-lang/yasm-0.6.2 )
+	x86? ( ${ASM_DEP} )
 	x86-fbsd? ( ${ASM_DEP} )
-	virtual/pkgconfig
-"
-if [ "${PV#9999}" = "${PV}" ] ; then
-	S=${WORKDIR}/${MY_P}
-fi
+	virtual/pkgconfig"
 
 src_configure() {
 	tc-export CC
 
-	local myconf=""
-	use debug && myconf+=" --enable-debug"
-	use ffmpeg || myconf+=" --disable-lavf --disable-swscale"
-	use ffmpegsource || myconf+=" --disable-ffms"
-	use mp4 || myconf+=" --disable-gpac"
-	use threads || myconf+=" --disable-thread"
+	# let upstream pick the optimization level by default
+	use custom-cflags || filter-flags -O?
 
 	./configure \
 		--prefix="${EPREFIX}"/usr \
 		--libdir="${EPREFIX}"/usr/$(get_libdir) \
-		--disable-avs \
-		--extra-asflags="${ASFLAGS}" \
-		--extra-cflags="${CFLAGS}" \
-		--extra-ldflags="${LDFLAGS}" \
-		--host="${CHOST}" \
 		--system-libx264 \
-		${myconf} || die
+		--host="${CHOST}" \
+		$(usex 10bit "--bit-depth=10" "") \
+		$(usex avs "" "--disable-avs") \
+		$(usex debug "--enable-debug" "") \
+		$(usex ffmpeg "" "--disable-lavf --disable-swscale") \
+		$(usex ffmpegsource "" "--disable-ffms") \
+		$(usex interlaced "" "--disable-interlaced") \
+		$(usex mp4 "" "--disable-gpac") \
+		$(usex threads "" "--disable-thread") || die
+
+	# this is a nasty workaround for bug #376925 for x264 that also applies
+	# here, needed because as upstream doesn't like us fiddling with their CFLAGS
+	if use custom-cflags; then
+		local cflags
+		cflags="$(grep "^CFLAGS=" config.mak | sed 's/CFLAGS=//')"
+		cflags="${cflags//$(get-flag O)/}"
+		cflags="${cflags//-O? /$(get-flag O) }"
+		cflags="${cflags//-g /}"
+		sed -i "s:^CFLAGS=.*:CFLAGS=${cflags//:/\\:}:" config.mak
+	fi
 }