Version bump

(Portage version: 2.1.2.11)

3 files changed, 134 insertions, 1 deletions

diff --git a/media-video/transcode/ChangeLog b/media-video/transcode/ChangeLog
index 38a5dd079605..69d6f8ceee47 100644
--- a/media-video/transcode/ChangeLog
+++ b/media-video/transcode/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/transcode
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v 1.183 2007/07/27 02:55:29 beandog Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v 1.184 2007/08/15 15:05:40 beandog Exp $
+
+*transcode-1.0.4_rc3 (15 Aug 2007)
+
+  15 Aug 2007; Steve Dibb <beandog@gentoo.org> +transcode-1.0.4_rc3.ebuild:
+  Version bump
 
 *transcode-1.1.0_pre20070705 (27 Jul 2007)
 
diff --git a/media-video/transcode/files/digest-transcode-1.0.4_rc3 b/media-video/transcode/files/digest-transcode-1.0.4_rc3
new file mode 100644
index 000000000000..82171d5e7f49
--- /dev/null
+++ b/media-video/transcode/files/digest-transcode-1.0.4_rc3
@@ -0,0 +1,3 @@
+MD5 db852052af77fd76083bf903a72990aa transcode-1.0.4rc3.tar.bz2 2273578
+RMD160 f5a8a7ea88229d78cca7b83a7f3a0958c7c86e47 transcode-1.0.4rc3.tar.bz2 2273578
+SHA256 4de09aaa8f7036fba390701d97b94d0defba8520ef7998e52727aace3fcb3abe transcode-1.0.4rc3.tar.bz2 2273578
diff --git a/media-video/transcode/transcode-1.0.4_rc3.ebuild b/media-video/transcode/transcode-1.0.4_rc3.ebuild
new file mode 100644
index 000000000000..8c7d8a1beb17
--- /dev/null
+++ b/media-video/transcode/transcode-1.0.4_rc3.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/transcode-1.0.4_rc3.ebuild,v 1.1 2007/08/15 15:05:40 beandog Exp $
+
+WANT_AUTOMAKE=1.8
+
+inherit libtool flag-o-matic eutils multilib autotools
+
+MY_P=${P/_/}
+
+DESCRIPTION="video stream processing tool"
+HOMEPAGE="http://www.transcoding.org/cgi-bin/transcode"
+SRC_URI="http://fromani.exit1.org/${MY_P}.tar.bz2"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="X 3dnow a52 altivec dv dvdread extrafilters mp3 fame truetype iconv
+imagemagick jpeg lzo mjpeg mpeg mmx network ogg oss vorbis quicktime sdl sse sse2 theora v4l2 xvid xml"
+
+S=${WORKDIR}/${MY_P}
+
+RDEPEND="a52? ( >=media-libs/a52dec-0.7.4 )
+	dv? ( >=media-libs/libdv-0.99 )
+	dvdread? ( >=media-libs/libdvdread-0.9.0 )
+	xvid? ( >=media-libs/xvid-1.0.2 )
+	mjpeg? ( >=media-video/mjpegtools-1.6.2-r3 )
+	lzo? ( =dev-libs/lzo-1* )
+	fame? ( >=media-libs/libfame-0.9.1 )
+	imagemagick? ( >=media-gfx/imagemagick-5.5.6.0 )
+	mpeg? ( >=media-libs/libmpeg3-1.7 )
+	mp3? ( >=media-sound/lame-3.93 )
+	sdl? ( media-libs/libsdl )
+	quicktime? ( >=media-libs/libquicktime-0.9.8 )
+	vorbis? ( media-libs/libvorbis )
+	ogg? ( media-libs/libogg )
+	theora? ( media-libs/libtheora )
+	jpeg? ( media-libs/jpeg )
+	truetype? ( >=media-libs/freetype-2 )
+	>=media-video/ffmpeg-0.4.9_p20050226-r3
+	|| ( sys-libs/glibc dev-libs/libiconv )
+	>=media-libs/libmpeg2-0.4.0b
+	xml? ( dev-libs/libxml2 )
+	X? ( x11-libs/libXaw
+		x11-libs/libXv )"
+
+DEPEND="${RDEPEND}
+	v4l2? ( >=sys-kernel/linux-headers-2.6.11 )"
+# Make sure the assembler USE flags are unmasked on amd64
+# Remove this once default-linux/amd64/2006.1 is deprecated
+DEPEND="${DEPEND} amd64? ( >=sys-apps/portage-2.1.2 )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	sed -i -e "s:\$(datadir)/doc/transcode:\$(datadir)/doc/${PF}:" \
+		"${S}"/Makefile.am "${S}"/docs/Makefile.am "${S}"/docs/html/Makefile.am \
+		"${S}"/docs/release-notes/Makefile.am
+
+	eautoreconf
+}
+
+src_compile() {
+	filter-flags -maltivec -mabi=altivec -momit-leaf-frame-pointer
+	#145849
+	use amd64 && filter-flags -fweb
+
+	if use ppc || use ppc64 ; then
+		append-flags -U__ALTIVEC__
+	fi
+
+	append-flags -DDCT_YUV_PRECISION=1
+
+	use xvid && myconf="${myconf} --with-default-xvid=xvid4"
+	# Follow upstreams suggestion about a52, libac3 is deprecated
+	use a52 && myconf="${myconf} --enable-a52 --enable-a52-default-decoder"
+	myconf="${myconf} \
+		$(use_enable mmx) \
+		$(use_enable sse) \
+		$(use_enable sse2) \
+		$(use_enable 3dnow) \
+		$(use_enable altivec) \
+		$(use_enable network netstream) \
+		$(use_enable truetype freetype2) \
+		$(use_enable v4l2 v4l) \
+		$(use_enable mp3 lame) \
+		$(use_enable ogg) \
+		$(use_enable oss) \
+		$(use_enable vorbis) \
+		$(use_enable theora) \
+		$(use_enable dvdread libdvdread) \
+		$(use_enable dv libdv) \
+		$(use_enable quicktime libquicktime) \
+		$(use_enable lzo) \
+		$(use_enable iconv) \
+		$(use_enable mpeg libmpeg3) \
+		$(use_enable xml libxml2) \
+		$(use_enable mjpeg mjpegtools) \
+		$(use_enable sdl) \
+		$(use_enable fame libfame) \
+		$(use_enable imagemagick) \
+		$(use_enable jpeg libjpeg) \
+		$(use_with X x) \
+		--with-mod-path=/usr/$(get_libdir)/transcode \
+		--with-libpostproc-builddir="/usr/$(get_libdir)" \
+		--disable-avifile \
+		--disable-xio"
+		econf ${myconf} || die
+
+	emake all || die
+}
+
+src_install () {
+	make DESTDIR="${D}" install || die
+
+	#do not install the filters that make dvdrip hang unless we ask for them
+	if ! use extrafilters ; then
+		rm "${D}"/usr/$(get_libdir)/transcode/filter_logo.*
+		rm "${D}"/usr/$(get_libdir)/transcode/filter_compare.*
+	fi
+
+	dodoc AUTHORS ChangeLog README TODO README-1.0.1
+	dodoc docs/*
+	dohtml docs/html/*
+}