Version bump. Bug #510048

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

3 files changed, 82 insertions, 4 deletions

diff --git a/media-sound/wildmidi/ChangeLog b/media-sound/wildmidi/ChangeLog
index 00de6b50f1b9..ad9f0c5c7530 100644
--- a/media-sound/wildmidi/ChangeLog
+++ b/media-sound/wildmidi/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/wildmidi
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/wildmidi/ChangeLog,v 1.26 2013/02/16 08:11:46 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/wildmidi/ChangeLog,v 1.27 2014/05/21 20:33:36 hwoarang Exp $
+
+*wildmidi-0.3.6 (21 May 2014)
+
+  21 May 2014; Markos Chandras <hwoarang@gentoo.org> +wildmidi-0.3.6.ebuild,
+  metadata.xml:
+  Version bump. Bug #510048
 
   16 Feb 2013; Pacho Ramos <pacho@gentoo.org> wildmidi-0.2.3.5.ebuild:
   Don't show elog messages always (#457596)
diff --git a/media-sound/wildmidi/metadata.xml b/media-sound/wildmidi/metadata.xml
index 5e3a61a90139..006d246df309 100644
--- a/media-sound/wildmidi/metadata.xml
+++ b/media-sound/wildmidi/metadata.xml
@@ -5,7 +5,8 @@
 <email>hwoarang@gentoo.org</email>
 <name>Markos Chandras</name>
 </maintainer>
-<longdescription lang="en">
-</longdescription>
+<use>
+<flag name='player'>Install the wildmidi player</flag>
+</use>
 </pkgmetadata>
 
diff --git a/media-sound/wildmidi/wildmidi-0.3.6.ebuild b/media-sound/wildmidi/wildmidi-0.3.6.ebuild
new file mode 100644
index 000000000000..bee80eb349a2
--- /dev/null
+++ b/media-sound/wildmidi/wildmidi-0.3.6.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/wildmidi/wildmidi-0.3.6.ebuild,v 1.1 2014/05/21 20:33:36 hwoarang Exp $
+
+EAPI=5
+inherit cmake-utils readme.gentoo
+
+DESCRIPTION="Midi processing library and a midi player using the gus patch set"
+HOMEPAGE="http://www.mindwerks.net/projects/wildmidi/"
+SRC_URI="http://github.com/Mindwerks/${PN}/archive/${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="+alsa openal oss +player"
+
+DEPEND="player? (
+	alsa? ( media-libs/alsa-lib )
+	openal? ( media-libs/openal )
+	)"
+RDEPEND="${DEPEND}
+	media-sound/timidity-freepats"
+
+REQUIRED_USE="player? ( ^^ ( alsa oss openal ) )"
+
+DOC_CONTENTS="${PN} is using timidity-freepats for midi playback.
+	A default configuration file was placed on /etc/${PN}/${PN}.cfg.
+	For more information please read the ${PN}.cfg manpage."
+
+S="${WORKDIR}"/${PN}-${P}
+
+src_prepare() {
+	# alsa openal oss only make sense if player is enabled. See CMakeLists.txt
+	if ! use player && (use alsa || use openal || use oss); then
+		ewarn
+		ewarn "The 'alsa', 'openal' and 'oss' use flags only make sense if"
+		ewarn "the 'player' use flags is selected and as a result they will be"
+		ewarn "ignored in this build"
+		ewarn
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_want alsa)
+		$(cmake-utils_use_want openal)
+		$(cmake-utils_use_want oss)
+		$(cmake-utils_use_want player)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	find "${D}" -name '*.la' -exec rm -f {} +
+	insinto /etc/${PN}/
+	doins cfg/${PN}.cfg
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/etc/${PN}.cfg ]]; then
+		elog
+		elog "Old /etc/${PN}.cfg detected!"
+		elog "Please migrate your configuration file to"
+		elog "/etc/${PN}/ directory which is now the default"
+		elog "location for the ${PN} configuration file."
+		elog
+	fi
+}