Version bump

(Portage version: 2.2.0_alpha27/cvs/Linux x86_64)

2 files changed, 194 insertions, 1 deletions

diff --git a/media-sound/mpd/ChangeLog b/media-sound/mpd/ChangeLog
index e4df20416bea..f384f4883409 100644
--- a/media-sound/mpd/ChangeLog
+++ b/media-sound/mpd/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.241 2011/03/16 19:30:54 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.242 2011/03/19 08:59:00 angelos Exp $
+
+*mpd-0.16.2 (19 Mar 2011)
+
+  19 Mar 2011; Christoph Mende <angelos@gentoo.org> +mpd-0.16.2.ebuild:
+  Version bump
 
   16 Mar 2011; Kacper Kowalik <xarthisius@gentoo.org> mpd-0.15.15.ebuild:
   ppc64 stable wrt #348798
diff --git a/media-sound/mpd/mpd-0.16.2.ebuild b/media-sound/mpd/mpd-0.16.2.ebuild
new file mode 100644
index 000000000000..dc6c0d7910ce
--- /dev/null
+++ b/media-sound/mpd/mpd-0.16.2.ebuild
@@ -0,0 +1,188 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.16.2.ebuild,v 1.1 2011/03/19 08:59:00 angelos Exp $
+
+EAPI=4
+inherit eutils flag-o-matic linux-info multilib
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+SRC_URI="mirror://sourceforge/musicpd/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="aac +alsa ao audiofile bzip2 cdio cue +curl debug +fifo +ffmpeg flac
+fluidsynth profile +id3 inotify ipv6 jack lame lastfmradio libmms libsamplerate
++mad mikmod modplug mpg123 musepack +network ogg openal oss pipe pulseaudio sid
+sndfile sqlite tcpd twolame unicode vorbis wavpack wildmidi zeroconf zip"
+
+REQUIRED_USE="|| ( alsa ao fifo jack network openal oss pipe pulseaudio )
+	|| ( aac audiofile ffmpeg flac fluidsynth mad mikmod modplug mpg123 musepack
+			ogg flac sid vorbis wavpack wildmidi )
+	network? ( || ( audiofile flac lame twolame vorbis ) )
+	lastfmradio? ( curl )"
+
+RDEPEND="!sys-cluster/mpich2
+	dev-libs/glib:2
+	aac? ( media-libs/faad2 )
+	alsa? ( media-sound/alsa-utils )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	network? ( >=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
+	id3? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	libmms? ( media-libs/libmms )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplay:2 )
+	sndfile? ( media-libs/libsndfile )
+	sqlite? ( dev-db/sqlite:3 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use inotify; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	epatch "${FILESDIR}"/${PN}-0.16.conf.patch
+}
+
+src_configure() {
+	local mpdconf="--enable-tcp --enable-un	--disable-documentation
+		--disable-ffado --disable-gme --enable-largefile
+		--disable-mvp --docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use flac && use ogg; then
+		mpdconf+=" --enable-oggflac"
+	else
+		mpdconf+=" --disable-oggflac"
+	fi
+
+	if use lastfmradio && use curl; then
+		mpdconf+=" --enable-lastfm"
+	else
+		mpdconf+=" --disable-lastfm"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	cd "${S}"
+
+	econf \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable ao) \
+		$(use_enable audiofile) \
+		$(use_with zeroconf zeroconf avahi) \
+		$(use_enable bzip2) \
+		$(use_enable cdio iso9660) \
+		$(use_enable cue) \
+		$(use_enable curl) \
+		$(use_enable debug) \
+		$(use_enable ffmpeg) \
+		$(use_enable fifo) \
+		$(use_enable flac) \
+		$(use_enable fluidsynth) \
+		$(use_enable jack) \
+		$(use_enable id3) \
+		$(use_enable inotify) \
+		$(use_enable ipv6) \
+		$(use_enable libmms mms) \
+		$(use_enable libsamplerate lsr) \
+		$(use_enable mad) \
+		$(use_enable mikmod) \
+		$(use_enable modplug) \
+		$(use_enable mpg123) \
+		$(use_enable musepack mpc) \
+		$(use_enable openal) \
+		$(use_enable oss) \
+		$(use_enable pipe pipe-output) \
+		$(use_enable profile gprof) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable sid sidplay) \
+		$(use_enable sndfile sndfile) \
+		$(use_enable sqlite) \
+		$(use_enable tcpd libwrap) \
+		$(use_enable vorbis) \
+		$(use_enable wavpack) \
+		$(use_enable wildmidi) \
+		$(use_enable zip zzip) \
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	insinto /etc
+	newins doc/mpdconf.example mpd.conf
+
+	newinitd "${FILESDIR}"/mpd.init mpd
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${D}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make"
+	elog "sure that MPD's pid_file is unset."
+
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}