Version bump. Bump to eapi 5. Use qt4_get_bindir for correct lupdate path.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x4FDF9CFD2FAC514E!)

2 files changed, 64 insertions, 2 deletions

diff --git a/media-sound/qsynth/ChangeLog b/media-sound/qsynth/ChangeLog
index 4c5f5c5d37c4..8247d99bcf22 100644
--- a/media-sound/qsynth/ChangeLog
+++ b/media-sound/qsynth/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/qsynth
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.60 2014/01/18 12:35:37 aballier Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.61 2015/03/26 13:31:22 yngwin Exp $
+
+*qsynth-0.3.9 (26 Mar 2015)
+
+  26 Mar 2015; Ben de Groot <yngwin@gentoo.org> +qsynth-0.3.9.ebuild:
+  Version bump. Bump to eapi 5. Use qt4_get_bindir for correct lupdate path.
 
 *qsynth-0.3.8 (18 Jan 2014)
 
diff --git a/media-sound/qsynth/qsynth-0.3.9.ebuild b/media-sound/qsynth/qsynth-0.3.9.ebuild
new file mode 100644
index 000000000000..a16f464bfacd
--- /dev/null
+++ b/media-sound/qsynth/qsynth-0.3.9.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/qsynth-0.3.9.ebuild,v 1.1 2015/03/26 13:31:22 yngwin Exp $
+
+EAPI=5
+LANGS="cs de fr ru sr"
+
+inherit qt4-r2 eutils
+
+DESCRIPTION="A Qt application to control FluidSynth"
+HOMEPAGE="http://qsynth.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qsynth/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug jack alsa pulseaudio"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+DEPEND=">=dev-qt/qtcore-4.2:4
+	>=dev-qt/qtgui-4.2:4
+	>=media-sound/fluidsynth-1.0.7a[jack?,alsa?,pulseaudio?]
+	x11-libs/libX11
+	!pulseaudio? ( !jack? ( !alsa? ( >=media-sound/fluidsynth-1.0.7a[oss] ) ) )"
+RDEPEND="${DEPEND}"
+
+DOCS="AUTHORS ChangeLog README TODO TRANSLATORS"
+
+src_configure() {
+	econf $(use_enable debug)
+	eqmake4 "${PN}.pro" -o "${PN}.mak"
+}
+
+src_compile() {
+	"$(qt4_get_bindir)"/lupdate "${PN}.pro" || die "lupdate failed"
+	qt4-r2_src_compile
+}
+
+src_install () {
+	qt4-r2_src_install
+
+	# The desktop file is invalid, and we also change the command
+	# depending on useflags
+	rm -rf "${D}/usr/share/applications/qsynth.desktop"
+
+	local cmd
+	if use jack; then
+		cmd="qsynth"
+	elif use pulseaudio; then
+		cmd="qsynth -a pulseaudio"
+	elif use alsa; then
+		cmd="qsynth -a alsa"
+	else
+		cmd="qsynth -a oss"
+	fi
+
+	make_desktop_entry "${cmd}" Qsynth qsynth
+}