Version bump wrt #464726 by Lars Wendler

(Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 50 insertions, 1 deletions

diff --git a/media-libs/libpng/ChangeLog b/media-libs/libpng/ChangeLog
index affb2d543879..4bc12e2e2774 100644
--- a/media-libs/libpng/ChangeLog
+++ b/media-libs/libpng/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libpng
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.388 2013/02/18 01:08:25 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.389 2013/04/05 14:58:49 ssuominen Exp $
+
+*libpng-1.5.15 (05 Apr 2013)
+
+  05 Apr 2013; Samuli Suominen <ssuominen@gentoo.org> +libpng-1.5.15.ebuild:
+  Version bump wrt #464726 by Lars Wendler
 
   18 Feb 2013; Zac Medico <zmedico@gentoo.org> libpng-1.5.14.ebuild:
   Add ~arm-linux keyword.
diff --git a/media-libs/libpng/libpng-1.5.15.ebuild b/media-libs/libpng/libpng-1.5.15.ebuild
new file mode 100644
index 000000000000..647e01743046
--- /dev/null
+++ b/media-libs/libpng/libpng-1.5.15.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.5.15.ebuild,v 1.1 2013/04/05 14:58:49 ssuominen Exp $
+
+EAPI=5
+
+inherit eutils libtool
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
+
+LICENSE="libpng"
+SLOT="0" # SLOT="0/15"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng neon static-libs"
+
+RDEPEND="sys-libs/zlib:="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+
+src_prepare() {
+	if use apng; then
+		epatch "${WORKDIR}"/${PN}-*-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--enable-arm-neon=$(usex neon on off)
+}
+
+src_install() {
+	default
+	# Even prune_libtool --all fails to remove libpng.la dead symlink wrt #436996
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}