New snapshot, cleanup: use add_kdebase_dep, merge with live ebuild, EAPI3

(Portage version: 2.2_rc94/cvs/Linux x86_64)

3 files changed, 76 insertions, 8 deletions

diff --git a/kde-misc/knetworkmanager/ChangeLog b/kde-misc/knetworkmanager/ChangeLog
index ef5c7f4c055b..6efc4724090c 100644
--- a/kde-misc/knetworkmanager/ChangeLog
+++ b/kde-misc/knetworkmanager/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for kde-misc/knetworkmanager
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-misc/knetworkmanager/ChangeLog,v 1.18 2010/09/08 12:23:18 tampakrap Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-misc/knetworkmanager/ChangeLog,v 1.19 2010/10/12 20:05:45 tampakrap Exp $
+
+*knetworkmanager-4.4.0_p20101012 (12 Oct 2010)
+
+  12 Oct 2010; Theo Chatzimichos <tampakrap@gentoo.org>
+  knetworkmanager-4.4.0_p20100820.ebuild,
+  +knetworkmanager-4.4.0_p20101012.ebuild:
+  New snapshot, cleanup: use add_kdebase_dep, merge with live ebuild, EAPI3
 
   08 Sep 2010; Theo Chatzimichos <tampakrap@gentoo.org>
   -knetworkmanager-4.4.0_p20100331.ebuild:
diff --git a/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20100820.ebuild b/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20100820.ebuild
index 880bfc3e5c4f..15abf5143bff 100644
--- a/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20100820.ebuild
+++ b/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20100820.ebuild
@@ -1,16 +1,20 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20100820.ebuild,v 1.1 2010/08/20 23:49:34 tampakrap Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20100820.ebuild,v 1.2 2010/10/12 20:05:45 tampakrap Exp $
 
-EAPI="2"
+EAPI=3
 
-QT_MINIMAL="4.6.0_beta"
+KMNAME="extragear/base"
+KMMODULE="networkmanagement"
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+fi
 
 inherit kde4-base
 
 DESCRIPTION="KDE frontend for NetworkManager"
 HOMEPAGE="http://kde.org/"
-SRC_URI="http://dev.gentoo.org/~tampakrap/${P}.tar.bz2"
 
 LICENSE="GPL-2 LGPL-2"
 KEYWORDS="~amd64 ~x86"
@@ -18,14 +22,16 @@ SLOT="4"
 IUSE="consolekit debug +networkmanager wicd"
 
 DEPEND="
-	!kde-misc/networkmanager-applet
-	>=kde-base/solid-${KDE_MINIMAL}[networkmanager?,wicd?]
-	!wicd? ( >=kde-base/solid-${KDE_MINIMAL}[networkmanager] )
+	$(add_kdebase_dep solid 'networkmanager?,wicd?')
+	net-misc/mobile-broadband-provider-info
 	>=net-misc/networkmanager-0.7
 	consolekit? ( sys-auth/consolekit )
+	!wicd? ( $(add_kdebase_dep solid 'networkmanager') )
 "
 RDEPEND="${DEPEND}"
 
+RESTRICT="test"
+
 src_prepare() {
 	kde4-base_src_prepare
 
@@ -37,6 +43,7 @@ src_prepare() {
 			|| die "Fixing dbus policy failed"
 	fi
 
+	# Makes it KDE 4.4 compatible
 	sed -i -e 's/KCMUTILS/KUTILS/' "${S}/applet/CMakeLists.txt" || die "sed died"
 }
 
diff --git a/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20101012.ebuild b/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20101012.ebuild
new file mode 100644
index 000000000000..e5ec2374111f
--- /dev/null
+++ b/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20101012.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-misc/knetworkmanager/knetworkmanager-4.4.0_p20101012.ebuild,v 1.1 2010/10/12 20:05:45 tampakrap Exp $
+
+EAPI=3
+
+KMNAME="extragear/base"
+KMMODULE="knetworkmanagement"
+KDE_MINIMAL="4.5"
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+fi
+
+inherit kde4-base
+
+DESCRIPTION="KDE frontend for NetworkManager"
+HOMEPAGE="http://kde.org/"
+
+LICENSE="GPL-2 LGPL-2"
+KEYWORDS="~amd64 ~x86"
+SLOT="4"
+IUSE="consolekit debug +networkmanager wicd"
+
+DEPEND="
+	$(add_kdebase_dep solid 'networkmanager?,wicd?')
+	net-misc/mobile-broadband-provider-info
+	>=net-misc/networkmanager-0.7
+	consolekit? ( sys-auth/consolekit )
+	!wicd? ( $(add_kdebase_dep solid 'networkmanager') )
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	if ! use consolekit; then
+		# Fix dbus policy
+		sed -i \
+			-e 's/at_console=".*"/group="plugdev"/' \
+			"${S}/NetworkManager-kde4.conf" \
+			|| die "Fixing dbus policy failed"
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DDBUS_SYSTEM_POLICY_DIR=/etc/dbus-1/system.d
+	)
+
+	kde4-base_src_configure
+}