Version bump KDE SC 4.13.2

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

2 files changed, 77 insertions, 1 deletions

diff --git a/kde-base/qtruby/ChangeLog b/kde-base/qtruby/ChangeLog
index 04b4411f7908..17735be5e553 100644
--- a/kde-base/qtruby/ChangeLog
+++ b/kde-base/qtruby/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/qtruby
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/ChangeLog,v 1.213 2014/05/13 17:43:28 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/ChangeLog,v 1.214 2014/06/15 16:56:18 kensington Exp $
+
+*qtruby-4.13.2 (15 Jun 2014)
+
+  15 Jun 2014; Michael Palimaka <kensington@gentoo.org> +qtruby-4.13.2.ebuild:
+  Version bump KDE SC 4.13.2
 
 *qtruby-4.13.1 (13 May 2014)
 
diff --git a/kde-base/qtruby/qtruby-4.13.2.ebuild b/kde-base/qtruby/qtruby-4.13.2.ebuild
new file mode 100644
index 000000000000..38246e58b55b
--- /dev/null
+++ b/kde-base/qtruby/qtruby-4.13.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/qtruby-4.13.2.ebuild,v 1.1 2014/06/15 16:56:18 kensington Exp $
+
+EAPI=5
+
+OPENGL_REQUIRED="always"
+DECLARATIVE_REQUIRED="optional"
+KDE_REQUIRED="never"
+USE_RUBY="ruby19"
+# Only one ruby version is supported:
+# 1) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 2) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-base ruby-ng
+
+DESCRIPTION="Qt Ruby bindings"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug phonon qscintilla qwt webkit"
+HOMEPAGE="http://techbase.kde.org/Development/Languages/Ruby"
+
+DEPEND="
+	$(add_kdebase_dep smokeqt 'declarative?,opengl,phonon?,qscintilla?,qwt?,webkit?')
+"
+
+RDEPEND="${DEPEND}
+"
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-base_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-base_src_prepare
+}
+
+each_ruby_configure() {
+	local CMAKE_USE_DIR=${S}
+	mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+		$(cmake-utils_use_disable declarative QtDeclarative)
+		$(cmake-utils_use_with phonon)
+		$(cmake-utils_use_with qscintilla QScintilla)
+		$(cmake-utils_use_with qwt Qwt5)
+		$(cmake-utils_use_disable webkit QtWebKit)
+	)
+	kde4-base_src_configure
+}
+
+each_ruby_compile() {
+	local CMAKE_USE_DIR=${S}
+	kde4-base_src_compile
+}
+
+each_ruby_install() {
+	local CMAKE_USE_DIR=${S}
+	kde4-base_src_install
+}