Version bump KDE SC 4.8.1

(Portage version: 2.1.10.49/cvs/Linux x86_64)

2 files changed, 79 insertions, 1 deletions

diff --git a/kde-base/kwin/ChangeLog b/kde-base/kwin/ChangeLog
index 3504c402aaa9..78c75df6a50e 100644
--- a/kde-base/kwin/ChangeLog
+++ b/kde-base/kwin/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kwin
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/ChangeLog,v 1.264 2012/02/21 15:34:52 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/ChangeLog,v 1.265 2012/03/06 23:35:21 dilfridge Exp $
+
+*kwin-4.8.1 (06 Mar 2012)
+
+  06 Mar 2012; Andreas K. Huettel <dilfridge@gentoo.org> +kwin-4.8.1.ebuild:
+  Version bump KDE SC 4.8.1
 
   21 Feb 2012; Johannes Huber <johu@gentoo.org>
   -files/kwin-4.6.3-desktopnames.patch, -files/kwin-4.6.5-mesadri.patch,
diff --git a/kde-base/kwin/kwin-4.8.1.ebuild b/kde-base/kwin/kwin-4.8.1.ebuild
new file mode 100644
index 000000000000..c075676fcb71
--- /dev/null
+++ b/kde-base/kwin/kwin-4.8.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/kwin-4.8.1.ebuild,v 1.1 2012/03/06 23:35:21 dilfridge Exp $
+
+EAPI=4
+
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="optional"
+inherit kde4-meta
+
+DESCRIPTION="KDE window manager"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gles xinerama"
+
+COMMONDEPEND="
+	$(add_kdebase_dep kactivities)
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep liboxygenstyle)
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXfixes
+	>=x11-libs/libXrandr-1.2.1
+	x11-libs/libXrender
+	opengl? ( >=media-libs/mesa-7.10 )
+	gles? (
+		|| (  ( >=media-libs/mesa-7.10[egl(+),gles] <media-libs/mesa-7.12[egl(+),gles] )
+			>=media-libs/mesa-7.12[egl(+),gles2] )
+	)
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/compositeproto
+	x11-proto/damageproto
+	x11-proto/fixesproto
+	x11-proto/randrproto
+	x11-proto/renderproto
+	xinerama? ( x11-proto/xineramaproto )
+"
+RDEPEND="${COMMONDEPEND}
+	x11-apps/scripts
+"
+
+KMEXTRACTONLY="
+	ksmserver/
+	libs/kephal/
+	libs/oxygen/
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.4.2-xinerama_cmake_automagic.patch"
+)
+
+# normally, you can use just gles or opengl or none
+#REQUIRED_USE="opengl? ( !gles ) gles? ( !opengl )"
+
+# right now, upstream requires opengl to always be enabled with gles
+REQUIRED_USE="gles? ( opengl )"
+
+src_configure() {
+	# FIXME Remove when activity API moved away from libkworkspace
+	append-cppflags "-I${EPREFIX}/usr/include/kworkspace"
+
+	mycmakeargs=(
+		$(cmake-utils_use_with gles OpenGLES)
+		$(cmake-utils_use gles KWIN_BUILD_WITH_OPENGLES)
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with xinerama X11_Xinerama)
+		-DWITH_X11_Xcomposite=ON
+	)
+
+	kde4-meta_src_configure
+}