Add KDE SC 4.5.2 =)

(Portage version: 2.2_rc88_p115/cvs/Linux x86_64, RepoMan options: --force)

2 files changed, 63 insertions, 1 deletions

diff --git a/kde-base/kdebase-kioslaves/ChangeLog b/kde-base/kdebase-kioslaves/ChangeLog
index 3e5c45bd8644..1e9ceb5a846a 100644
--- a/kde-base/kdebase-kioslaves/ChangeLog
+++ b/kde-base/kdebase-kioslaves/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kdebase-kioslaves
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-kioslaves/ChangeLog,v 1.207 2010/09/05 23:54:28 tampakrap Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-kioslaves/ChangeLog,v 1.208 2010/10/06 09:17:09 alexxy Exp $
+
+*kdebase-kioslaves-4.5.2 (05 Oct 2010)
+
+  05 Oct 2010; Alexey Shvetsov <alexxy@gentoo.org>
+  +kdebase-kioslaves-4.5.2.ebuild:
+  Version bump KDE SC 4.5.2
 
 *kdebase-kioslaves-4.5.1 (05 Sep 2010)
 
diff --git a/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.5.2.ebuild b/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.5.2.ebuild
new file mode 100644
index 000000000000..f5814a9d1f46
--- /dev/null
+++ b/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.5.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.5.2.ebuild,v 1.1 2010/10/06 09:17:09 alexxy Exp $
+
+EAPI="3"
+
+KDE_HANDBOOK="optional"
+KMNAME="kdebase-runtime"
+KMMODULE="kioslave"
+inherit kde4-meta
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+DESCRIPTION="kioslave: the kde VFS framework - kioslave plugins present a filesystem-like view of arbitrary data"
+IUSE="+bzip2 exif debug lzma openexr samba +sftp"
+
+# tests hang, last checked for 4.2.96
+RESTRICT="test"
+
+DEPEND="
+	!aqua? ( x11-libs/libXcursor )
+	bzip2? ( app-arch/bzip2 )
+	exif? ( media-gfx/exiv2 )
+	lzma? ( app-arch/xz-utils )
+	openexr? ( media-libs/openexr )
+	samba? (
+		|| (
+			=net-fs/samba-3.0*
+			>=net-fs/samba-3.4.6[smbclient]
+		)
+	)
+	sftp? ( >=net-libs/libssh-0.4.0[sftp] )
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep kdelibs 'bzip2?,lzma?')
+	$(add_kdebase_dep kdialog)
+	virtual/ssh
+	!aqua? ( !kernel_SunOS? ( virtual/eject ) )
+"
+
+KMEXTRA="
+	kioexec
+	kdeeject
+"
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_SLP=OFF
+		$(cmake-utils_use_with bzip2 BZip2)
+		$(cmake-utils_use_with exif Exiv2)
+		$(cmake-utils_use_with lzma LibLZMA)
+		$(cmake-utils_use_with openexr OpenEXR)
+		$(cmake-utils_use_with samba)
+		$(cmake-utils_use_with sftp LibSSH)
+	)
+	kde4-meta_src_configure
+}