Version bump KDE 4.2.3

(Portage version: 2.2_rc31/cvs/Linux x86_64, RepoMan options: --force)

2 files changed, 79 insertions, 1 deletions

diff --git a/kde-base/akonadi/ChangeLog b/kde-base/akonadi/ChangeLog
index 4ab19706e916..d62c548b6652 100644
--- a/kde-base/akonadi/ChangeLog
+++ b/kde-base/akonadi/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/akonadi
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/akonadi/ChangeLog,v 1.20 2009/04/17 06:03:22 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/akonadi/ChangeLog,v 1.21 2009/05/06 22:46:31 scarabeus Exp $
+
+*akonadi-4.2.3 (06 May 2009)
+
+  06 May 2009; Tomas Chvatal <scarabeus@gentoo.org> +akonadi-4.2.3.ebuild:
+  Version bump
 
   17 Apr 2009; Alexey Shvetsov <alexxy@gentoo.org> akonadi-4.2.2:
   Restore ~hppa keywords
diff --git a/kde-base/akonadi/akonadi-4.2.3.ebuild b/kde-base/akonadi/akonadi-4.2.3.ebuild
new file mode 100644
index 000000000000..718b121e7237
--- /dev/null
+++ b/kde-base/akonadi/akonadi-4.2.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/akonadi/akonadi-4.2.3.ebuild,v 1.1 2009/05/06 22:46:31 scarabeus Exp $
+
+EAPI="2"
+
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="An extensible cross-desktop storage service for PIM data and meta data"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+# add when libmapi becomes available with an ebuild
+#exchange
+IUSE="debug +semantic-desktop"
+
+# add when libmapi becomes available with an ebuild
+#exchange? ( net-libs/libmapi )
+# not sure about libxml2... - reavertm
+
+DEPEND="
+	dev-libs/boost
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=kde-base/kdelibs-${PV}:${SLOT}[kdeprefix=,semantic-desktop?]
+	>=kde-base/kdemaildir-${PV}:${SLOT}[kdeprefix=]
+	>=kde-base/libkdepim-${PV}:${SLOT}[kdeprefix=]
+	x11-misc/shared-mime-info
+"
+
+RDEPEND="${DEPEND}
+	>=app-office/akonadi-server-1.1[mysql]
+"
+
+KMEXTRACTONLY="
+	maildir/
+"
+
+src_prepare() {
+	if ! use semantic-desktop; then
+		sed -i -e "s/add_subdirectory( nepomuktag )//"\
+			akonadi/resources/CMakeLists.txt\
+			|| die "Failed to disable nepomuktag"
+	fi
+
+	kde4-meta_src_prepare
+}
+
+src_configure() {
+	# Set the dbus dirs, otherwise it searches in KDEDIR
+	mycmakeargs="${mycmakeargs}
+		-DAKONADI_DBUS_INTERFACES_INSTALL_DIR=/usr/share/dbus-1/interfaces
+		-DAKONADI_DBUS_SERVICES_INSTALL_DIR=/usr/share/dbus-1/services"
+	# replace with $(cmake-utils_use_with exchange OpenChange) when libmapi becomes available with an ebuild
+	mycmakeargs="${mycmakeargs}
+		-DWITH_LibXslt=ON
+		-DWITH_OpenChange=OFF
+		-DWITH_GNOKII=OFF
+		-DWITH_GLIB2=OFF
+		-DWITH_OpenSync=OFF
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use_with semantic-desktop Soprano)"
+
+	kde4-meta_src_configure
+}
+
+src_test() {
+	# disable broken test
+	sed -i -e '/mailserializerplugintest/ s/^/#DO_NOT_RUN_TEST /' \
+		"${S}"/akonadi/plugins/tests/CMakeLists.txt || \
+		die "sed to disable mailserializerplugintest failed."
+
+	kde4-meta_src_test
+}