Use new python eclasses, don't install .la files, disable static and other gnome2.eclass cleanups

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 82 insertions, 2 deletions

diff --git a/gnome-extra/gdesklets-core/ChangeLog b/gnome-extra/gdesklets-core/ChangeLog
index 67351e8922cd..ebecdf5beeb4 100644
--- a/gnome-extra/gdesklets-core/ChangeLog
+++ b/gnome-extra/gdesklets-core/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gdesklets-core
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog,v 1.157 2013/07/21 10:19:58 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gdesklets-core/ChangeLog,v 1.158 2014/12/02 21:55:39 pacho Exp $
+
+*gdesklets-core-0.36.3-r4 (02 Dec 2014)
+
+  02 Dec 2014; Pacho Ramos <pacho@gentoo.org> +gdesklets-core-0.36.3-r4.ebuild:
+  Use new python eclasses, don't install .la files, disable static and other
+  gnome2.eclass cleanups
 
   21 Jul 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Cleanup due http://www.gossamer-threads.com/lists/gentoo/dev/273644
diff --git a/gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r4.ebuild b/gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r4.ebuild
new file mode 100644
index 000000000000..2d7e7d946f45
--- /dev/null
+++ b/gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gdesklets-core/gdesklets-core-0.36.3-r4.ebuild,v 1.1 2014/12/02 21:55:39 pacho Exp $
+
+EAPI=5
+GCONF_DEBUG=no
+GNOME2_LA_PUNT="yes"
+PYTHON_REQ_USE="xml"
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools eutils gnome2 python-single-r1 multilib bash-completion-r1
+
+MY_PN=${PN/-core}
+MY_P=${MY_PN}-${PV}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="GNOME Desktop Applets: Core library for desktop applets"
+SRC_URI="http://gdesklets.de/files/${MY_P}.tar.bz2"
+HOMEPAGE="http://gdesklets.de"
+LICENSE="GPL-2"
+
+IUSE="dbus"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# is libgsf needed for runtime or just compiling?
+# only need expat for python-2.4, I think
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2:2
+	>=gnome-base/librsvg-2.8
+	>=gnome-base/libgtop-2.8.2
+	>=dev-python/pygtk-2.10[${PYTHON_USEDEP}]
+	>=dev-python/libbonobo-python-2.6[${PYTHON_USEDEP}]
+	>=dev-python/gconf-python-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.6:2[${PYTHON_USEDEP}]
+	>=dev-python/pyorbit-2.0.1[${PYTHON_USEDEP}]
+	|| ( >=dev-python/gnome-vfs-python-2.6[${PYTHON_USEDEP}] >=dev-python/libgnome-python-2.6[${PYTHON_USEDEP}] )
+	>=dev-libs/expat-1.95.8
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-.in-files.patch \
+		"${FILESDIR}"/${P}-CFLAGS.patch
+
+	python_fix_shebang .
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure --disable-static
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Install bash completion script
+	dobashcomp contrib/bash/gdesklets
+
+	# Install the gdesklets-control-getid script
+	insinto /usr/$(get_libdir)/gdesklets
+	insopts -m0555
+	doins "${FILESDIR}"/gdesklets-control-getid
+}