Version bump for Gnome 2.32

(Portage version: 2.1.9.14/cvs/Linux x86_64)

2 files changed, 60 insertions, 1 deletions

diff --git a/gnome-base/libgnome-keyring/ChangeLog b/gnome-base/libgnome-keyring/ChangeLog
index 09abc51dc70d..06d185bcb4ea 100644
--- a/gnome-base/libgnome-keyring/ChangeLog
+++ b/gnome-base/libgnome-keyring/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for gnome-base/libgnome-keyring
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome-keyring/ChangeLog,v 1.11 2010/10/09 15:15:38 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome-keyring/ChangeLog,v 1.12 2010/10/09 20:59:10 pacho Exp $
+
+*libgnome-keyring-2.32.0 (09 Oct 2010)
+
+  09 Oct 2010; Pacho Ramos <pacho@gentoo.org>
+  +libgnome-keyring-2.32.0.ebuild:
+  Version bump: Don't try to run daemon tests if DBus is not running, use
+  newer tar version for tarballs so we don't truncate file names, remove
+  erroneous egg-dbus dependency, other bugfixes and translation updates. Set
+  DOCS and remove DISABLE_DEPRECATED flags.
 
   09 Oct 2010; Pacho Ramos <pacho@gentoo.org>
   libgnome-keyring-2.30.1.ebuild:
diff --git a/gnome-base/libgnome-keyring/libgnome-keyring-2.32.0.ebuild b/gnome-base/libgnome-keyring/libgnome-keyring-2.32.0.ebuild
new file mode 100644
index 000000000000..49792b2c6494
--- /dev/null
+++ b/gnome-base/libgnome-keyring/libgnome-keyring-2.32.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome-keyring/libgnome-keyring-2.32.0.ebuild,v 1.1 2010/10/09 20:59:10 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+
+inherit gnome2
+
+DESCRIPTION="Compatibility library for accessing secrets"
+HOMEPAGE="http://live.gnome.org/GnomeKeyring"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux"
+IUSE="debug doc test"
+
+RDEPEND=">=sys-apps/dbus-1.0
+	gnome-base/gconf
+	>=gnome-base/gnome-keyring-2.29
+	!<gnome-base/gnome-keyring-2.29"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	doc? ( >=dev-util/gtk-doc-1.9 )"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		$(use_enable debug)
+		$(use_enable test tests)"
+	DOCS="AUTHORS ChangeLog NEWS README"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Remove silly CFLAGS
+	sed 's:CFLAGS="$CFLAGS -Werror:CFLAGS="$CFLAGS:' \
+		-i configure.in configure || die "sed failed"
+
+	# Remove DISABLE_DEPRECATED flags
+	sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' \
+		-i configure.in configure || die "sed 2 failed"
+}
+
+src_test() {
+	# Needed to run tests on console, bug #323661
+	dbus-launch emake check || die "tests failed"
+}