fix bug 196639 for guile, and bug 206896 too

(Portage version: 2.1.4)

1 files changed, 83 insertions, 0 deletions

diff --git a/dev-scheme/guile/guile-1.8.3-r2.ebuild b/dev-scheme/guile/guile-1.8.3-r2.ebuild
new file mode 100644
index 000000000000..7a545984cdb7
--- /dev/null
+++ b/dev-scheme/guile/guile-1.8.3-r2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/guile/guile-1.8.3-r2.ebuild,v 1.1 2008/01/23 16:47:11 hkbst Exp $
+
+inherit eutils autotools flag-o-matic
+
+DESCRIPTION="Scheme interpreter"
+HOMEPAGE="http://www.gnu.org/software/guile/"
+SRC_URI="mirror://gnu/guile/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+
+DEPEND=">=dev-libs/gmp-4.1 >=sys-devel/libtool-1.5.6 sys-devel/gettext"
+
+# Guile seems to contain some slotting support, /usr/share/guile/ is slotted,
+# but there are lots of collisions. Most in /usr/share/libguile. Therefore
+# I'm slotting this in the same slot as guile-1.6* for now.
+SLOT="12"
+MAJOR="1.8"
+
+IUSE="networking regex discouraged deprecated elisp nls debug-freelist debug-malloc debug threads"
+
+src_unpack() {
+	unpack ${A}; cd "${S}"
+
+	epatch "${FILESDIR}"/fix-reader-cr.diff
+
+	sed "s_sleep 999_sleep 1_" -i test-suite/tests/popen.test
+}
+
+src_compile() {
+	# see bug #178499
+	filter-flags -ftree-vectorize
+
+#will fail for me if posix is disabled or without modules -- hkBst
+	econf \
+		--disable-error-on-warning \
+		--disable-static \
+		--enable-posix \
+		$(use_enable networking) \
+		$(use_enable regex) \
+		$(use deprecated || use_enable discouraged) \
+		$(use_enable deprecated) \
+		$(use_enable elisp) \
+		$(use_enable nls) \
+		--disable-rpath \
+		$(use_enable debug-freelist) \
+		$(use_enable debug-malloc) \
+		$(use_enable debug guile-debug) \
+		$(use_with threads) \
+		--with-modules
+
+	emake || die "make failed"
+}
+
+src_install() {
+	einstall || die "install failed"
+
+	dodoc AUTHORS ChangeLog GUILE-VERSION HACKING NEWS README SNAPSHOTS THANKS
+
+	# texmacs needs this, closing bug #23493
+	dodir /etc/env.d
+	echo "GUILE_LOAD_PATH=\"/usr/share/guile/${MAJOR}\"" > "${D}"/etc/env.d/50guile
+
+	# necessary for registering slib, see bug 206896
+	dodir /usr/share/guile/site
+}
+
+pkg_postinst() {
+	[ "${ROOT}" == "/" ] && pkg_config
+}
+
+pkg_config() {
+	if has_version dev-scheme/slib; then
+		einfo "Registering slib with guile"
+		install_slib_for_guile
+	fi
+}
+
+pkg_prerm() {
+	rm -f "${ROOT}"/usr/share/guile/site/slibcat
+}