Revision bump to switch to new SRC_URI. Add ruby20, ruby21.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

2 files changed, 75 insertions, 1 deletions

diff --git a/dev-ruby/ruby-sdl/ChangeLog b/dev-ruby/ruby-sdl/ChangeLog
index 54635366a928..07be524fdae1 100644
--- a/dev-ruby/ruby-sdl/ChangeLog
+++ b/dev-ruby/ruby-sdl/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/ruby-sdl
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/ruby-sdl/ChangeLog,v 1.39 2014/04/24 17:42:59 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/ruby-sdl/ChangeLog,v 1.40 2014/06/04 05:19:42 graaff Exp $
+
+*ruby-sdl-2.1.2-r1 (04 Jun 2014)
+
+  04 Jun 2014; Hans de Graaff <graaff@gentoo.org> +ruby-sdl-2.1.2-r1.ebuild:
+  Revision bump to switch to new SRC_URI. Add ruby20, ruby21.
 
   24 Apr 2014; Manuel Rüger <mrueg@gentoo.org> ruby-sdl-2.1.2.ebuild:
   Remove ruby18 support.
diff --git a/dev-ruby/ruby-sdl/ruby-sdl-2.1.2-r1.ebuild b/dev-ruby/ruby-sdl/ruby-sdl-2.1.2-r1.ebuild
new file mode 100644
index 000000000000..24a6ebb132cd
--- /dev/null
+++ b/dev-ruby/ruby-sdl/ruby-sdl-2.1.2-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/ruby-sdl/ruby-sdl-2.1.2-r1.ebuild,v 1.1 2014/06/04 05:19:42 graaff Exp $
+
+EAPI=5
+USE_RUBY="ruby19 ruby20 ruby21"
+
+inherit eutils ruby-ng
+
+RELEASE="rel-${PV//./-}"
+RUBY_S="rubysdl-${RELEASE}"
+
+DESCRIPTION="Ruby/SDL: Ruby bindings for SDL"
+HOMEPAGE="http://www.kmc.gr.jp/~ohai/rubysdl.en.html"
+SRC_URI="https://github.com/ohai/rubysdl/archive/${RELEASE}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE="image mixer truetype mpeg sge"
+
+CDEPEND="
+	>=media-libs/libsdl-1.2.5
+	truetype? ( >=media-libs/sdl-ttf-2.0.6 )
+	image? ( >=media-libs/sdl-image-1.2.2 )
+	mixer? ( >=media-libs/sdl-mixer-1.2.4 )
+	mpeg? ( >=media-libs/smpeg-0.4.4-r1 )
+	sge? ( media-libs/sge )"
+DEPEND="${DEPEND} ${CDEPEND}"
+RDEPEND="${RDEPEND} ${CDEPEND}"
+
+each_ruby_configure() {
+	${RUBY} extconf.rb || die "extconf.rb failed"
+}
+
+each_ruby_compile() {
+	emake V=1 || die "emake failed"
+}
+
+each_ruby_install() {
+	emake V=1 DESTDIR="${D}" install || die "einstall failed"
+}
+
+all_ruby_install() {
+	dodoc README.en README.ja NEWS.en NEWS.ja
+	insinto /usr/share/doc/${P}/doc
+	doins doc-en/*
+	insinto /usr/share/doc/${P}/sample
+	doins sample/*
+}
+
+pkg_postinst () {
+	if ! use image || ! use mixer || ! use truetype || ! use mpeg || ! use sge; then
+		echo ""
+		ewarn "If any of the following packages are not installed, Ruby/SDL"
+		ewarn "will be missing some functionality. This is ok, but may"
+		ewarn "cause errors in Ruby/SDL programs that need these libraries:"
+		ewarn ""
+		ewarn "\tmedia-libs/sdl-image\tImage loading (PNG, JPEG, etc.)"
+		ewarn "\tmedia-libs/sdl-mixer\tSound mixing"
+		ewarn "\tmedia-libs/sdl-ttf\tTrueType Fonts"
+		ewarn "\tmedia-libs/sge\t\tVarious cool graphics extensions"
+		ewarn "\tmedia-libs/smpeg\tMPEG playback (including mp3)"
+		ewarn ""
+		ewarn "If you need the functionality offered by these libraries,"
+		ewarn "emerge the desired libraries, then re-emerge dev-ruby/rubysdl"
+		echo ""
+	fi
+}