Version bump for Gnome 3.14.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 64 insertions, 1 deletions

diff --git a/dev-python/pyatspi/ChangeLog b/dev-python/pyatspi/ChangeLog
index 03de7d98a340..dc4b7aacbb3a 100644
--- a/dev-python/pyatspi/ChangeLog
+++ b/dev-python/pyatspi/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyatspi
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyatspi/ChangeLog,v 1.50 2014/11/24 09:52:10 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyatspi/ChangeLog,v 1.51 2014/12/22 18:27:39 eva Exp $
+
+*pyatspi-2.14.0 (22 Dec 2014)
+
+  22 Dec 2014; Gilles Dartiguelongue <eva@gentoo.org> +pyatspi-2.14.0.ebuild:
+  Version bump for Gnome 3.14.
 
   24 Nov 2014; Pacho Ramos <pacho@gentoo.org>
   -files/pyatspi-2.2.0-AM_CHECK_PYMOD-pygtk.patch,
diff --git a/dev-python/pyatspi/pyatspi-2.14.0.ebuild b/dev-python/pyatspi/pyatspi-2.14.0.ebuild
new file mode 100644
index 000000000000..23b81df8c45d
--- /dev/null
+++ b/dev-python/pyatspi/pyatspi-2.14.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyatspi/pyatspi-2.14.0.ebuild,v 1.1 2014/12/22 18:27:39 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+
+inherit eutils gnome2 python-r1
+
+DESCRIPTION="Python binding to at-spi library"
+HOMEPAGE="http://live.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="" # test
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+	${PYTHON_DEPS}
+"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-${PV}[introspection]
+	!<gnome-extra/at-spi-1.32.0-r1
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=689957
+	epatch "${FILESDIR}/${PN}-2.6.0-examples-python3.patch"
+
+	gnome2_src_prepare
+
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure --disable-tests
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir gnome2_src_install
+
+	docinto examples
+	dodoc examples/*.py
+}