Version Bump

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

4 files changed, 141 insertions, 3 deletions

diff --git a/dev-python/pandas/ChangeLog b/dev-python/pandas/ChangeLog
index deec56ee8c3b..f8ad0f3cd114 100644
--- a/dev-python/pandas/ChangeLog
+++ b/dev-python/pandas/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pandas
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.42 2015/03/19 09:34:45 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.43 2015/04/07 10:10:31 jlec Exp $
+
+*pandas-0.16.0 (07 Apr 2015)
+
+  07 Apr 2015; Justin Lecher <jlec@gentoo.org> +pandas-0.16.0.ebuild,
+  pandas-0.15.2.ebuild, pandas-9999.ebuild:
+  Version Bump
 
   19 Mar 2015; Justin Lecher <jlec@gentoo.org> -pandas-0.15.0.ebuild,
   -pandas-0.15.1.ebuild, pandas-0.15.2.ebuild, pandas-9999.ebuild:
diff --git a/dev-python/pandas/pandas-0.15.2.ebuild b/dev-python/pandas/pandas-0.15.2.ebuild
index 94d725bd7b73..2033a6bbc83e 100644
--- a/dev-python/pandas/pandas-0.15.2.ebuild
+++ b/dev-python/pandas/pandas-0.15.2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-0.15.2.ebuild,v 1.4 2015/03/19 09:34:45 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-0.15.2.ebuild,v 1.5 2015/04/07 10:10:31 jlec Exp $
 
 EAPI=5
 
@@ -51,6 +51,7 @@ DEPEND="${CDEPEND}
 		)
 	test? (
 		${EXTRA_DEPEND}
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
 		dev-python/nose[${PYTHON_USEDEP}]
 		x11-misc/xclip
 		x11-misc/xsel
diff --git a/dev-python/pandas/pandas-0.16.0.ebuild b/dev-python/pandas/pandas-0.16.0.ebuild
new file mode 100644
index 000000000000..d6552661e6c3
--- /dev/null
+++ b/dev-python/pandas/pandas-0.16.0.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-0.16.0.ebuild,v 1.1 2015/04/07 10:10:31 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1 eutils flag-o-matic virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="http://pandas.pydata.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples excel html test R"
+
+EXTRA_DEPEND="
+	>=dev-python/google-api-python-client-1.2.0[$(python_gen_usedep python2_7 pypy)]
+	dev-python/openpyxl[${PYTHON_USEDEP}]
+	dev-python/pymysql[${PYTHON_USEDEP}]
+	dev-python/python-gflags[$(python_gen_usedep python2_7 pypy)]
+	dev-python/psycopg:2[${PYTHON_USEDEP}]
+	dev-python/statsmodels[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	dev-python/xlsxwriter[${PYTHON_USEDEP}]
+	"
+CDEPEND="
+	>dev-python/numpy-1.7[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.0[${PYTHON_USEDEP}]
+	!~dev-python/openpyxl-1.9.0[${PYTHON_USEDEP}]"
+DEPEND="${CDEPEND}
+	doc? (
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		dev-python/xlrd[$(python_gen_usedep 'python2_7')]
+		dev-python/xlwt[$(python_gen_usedep 'python2_7')]
+		x11-misc/xclip
+		)
+	test? (
+		${EXTRA_DEPEND}
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+		)"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="${CDEPEND}
+	>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+	dev-python/bottleneck[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/pytables[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	excel? (
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		dev-python/xlrd[$(python_gen_usedep 'python2_7')]
+		dev-python/xlwt[$(python_gen_usedep 'python2_7')]
+	)
+	html? (
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		|| (
+			dev-python/lxml[${PYTHON_USEDEP}]
+			dev-python/html5lib[${PYTHON_USEDEP}] )
+	)
+	R? ( dev-python/rpy[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.15.2-zoneinfo.patch
+)
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" -i doc/source/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. "${EPYTHON}" make.py html || die
+	fi
+}
+
+python_test() {
+	local test_pandas='not network and not disabled'
+	[[ -n "${FAST_PANDAS}" ]] && test_pandas+=' and not slow'
+	pushd  "${BUILD_DIR}"/lib > /dev/null
+	VIRTUALX_COMMAND="nosetests"
+	PYTHONPATH=. MPLCONFIGDIR=. HOME=. \
+		virtualmake --verbosity=3 -A "${test_pandas}" pandas
+	popd > /dev/null
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	local x
+	elog "Please install"
+	for x in ${EXTRA_DEPEND}; do
+		optfeature "additional functionality" "${x%%[*}"
+	done
+}
diff --git a/dev-python/pandas/pandas-9999.ebuild b/dev-python/pandas/pandas-9999.ebuild
index c804d96833c2..abbe01c25283 100644
--- a/dev-python/pandas/pandas-9999.ebuild
+++ b/dev-python/pandas/pandas-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-9999.ebuild,v 1.8 2015/03/19 09:34:45 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-9999.ebuild,v 1.9 2015/04/07 10:10:31 jlec Exp $
 
 EAPI=5
 
@@ -52,6 +52,7 @@ DEPEND="${CDEPEND}
 		)
 	test? (
 		${EXTRA_DEPEND}
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
 		dev-python/nose[${PYTHON_USEDEP}]
 		x11-misc/xclip
 		x11-misc/xsel