version bump & fix build without postscript

Signed-off-by: aballier@gentoo.org
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 73 insertions, 2 deletions

diff --git a/dev-ml/camlimages/ChangeLog b/dev-ml/camlimages/ChangeLog
index d243865a5030..08ff59b07bd0 100644
--- a/dev-ml/camlimages/ChangeLog
+++ b/dev-ml/camlimages/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/camlimages
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlimages/ChangeLog,v 1.37 2013/10/22 20:45:45 aballier Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlimages/ChangeLog,v 1.38 2014/10/23 10:57:44 aballier Exp $
+
+*camlimages-4.1.2 (23 Oct 2014)
+
+  23 Oct 2014; Alexis Ballier <aballier@gentoo.org> +camlimages-4.1.2.ebuild:
+  version bump & fix build without postscript
 
 *camlimages-4.1.1 (22 Oct 2013)
 
diff --git a/dev-ml/camlimages/camlimages-4.1.2.ebuild b/dev-ml/camlimages/camlimages-4.1.2.ebuild
new file mode 100644
index 000000000000..ef862bb82f47
--- /dev/null
+++ b/dev-ml/camlimages/camlimages-4.1.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlimages/camlimages-4.1.2.ebuild,v 1.1 2014/10/23 10:57:44 aballier Exp $
+
+EAPI=5
+
+inherit eutils vcs-snapshot findlib multilib
+
+DESCRIPTION="An image manipulation library for ocaml"
+HOMEPAGE="http://gallium.inria.fr/camlimages/"
+SRC_URI="http://bitbucket.org/camlspotter/camlimages/get/${PV}.tar.bz2 -> ${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc exif gif gtk jpeg png postscript tiff truetype X xpm"
+
+RDEPEND=">=dev-lang/ocaml-3.10.2:=[X?,ocamlopt]
+	exif? ( media-libs/libexif )
+	gif? ( media-libs/giflib )
+	gtk? ( dev-ml/lablgtk )
+	jpeg? ( virtual/jpeg )
+	tiff? ( media-libs/tiff )
+	png? ( >=media-libs/libpng-1.4:0 )
+	postscript? ( app-text/ghostscript-gpl )
+	truetype? ( >=media-libs/freetype-2 )
+	xpm? ( x11-libs/libXpm )
+	X? ( x11-apps/rgb )
+	sys-libs/zlib
+	"
+DEPEND="${DEPEND}
+	doc? ( dev-python/sphinx[latex] )
+	dev-util/omake
+	virtual/pkgconfig
+	dev-ml/findlib"
+
+camlimages_arg_want() {
+	echo "ARG_WANT_${2}=$(usex $1 1 0)"
+}
+
+src_compile() {
+	omake \
+		$(camlimages_arg_want exif        EXIF    ) \
+		$(camlimages_arg_want gif         GIF     ) \
+		$(camlimages_arg_want png         PNG     ) \
+		$(camlimages_arg_want jpeg        JPEG    ) \
+		$(camlimages_arg_want tiff        TIFF    ) \
+		$(camlimages_arg_want xpm         XPM     ) \
+		$(camlimages_arg_want postscript  GS      ) \
+		$(camlimages_arg_want gtk         LABLGTK2) \
+		$(camlimages_arg_want X           GRAPHICS) \
+		$(camlimages_arg_want truetype    FREETYPE) \
+		PATH_GS=/bin/true \
+		--force-dotomake || die
+
+	if use doc ; then
+		sphinx-build doc/sphinx sphinxdoc || die
+	fi
+}
+
+src_install() {
+	findlib_src_preinst
+	omake --force-dotomake DESTDIR="${D}" install || die
+	dodoc README.rst
+	use doc && dohtml -r sphinxdoc/*
+}