Version bump to 0.9.11. Add multilib support, bug 473624. Thanks to Jonathan Callen for the diff.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 974CA72A)

2 files changed, 61 insertions, 2 deletions

diff --git a/dev-libs/check/ChangeLog b/dev-libs/check/ChangeLog
index 146810f04dbe..6395b57a4f45 100644
--- a/dev-libs/check/ChangeLog
+++ b/dev-libs/check/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/check
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/check/ChangeLog,v 1.82 2013/04/24 07:18:22 binki Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/check/ChangeLog,v 1.83 2014/01/01 20:16:57 mattst88 Exp $
+
+*check-0.9.11 (01 Jan 2014)
+
+  01 Jan 2014; Matt Turner <mattst88@gentoo.org> +check-0.9.11.ebuild:
+  Version bump to 0.9.11. Add multilib support, bug 473624. Thanks to Jonathan
+  Callen for the diff.
 
 *check-0.9.10 (24 Apr 2013)
 
diff --git a/dev-libs/check/check-0.9.11.ebuild b/dev-libs/check/check-0.9.11.ebuild
new file mode 100644
index 000000000000..8a9636f24e51
--- /dev/null
+++ b/dev-libs/check/check-0.9.11.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/check/check-0.9.11.ebuild,v 1.1 2014/01/01 20:16:57 mattst88 Exp $
+
+EAPI=4
+
+AUTOTOOLS_PRUNE_LIBTOOL_FILES="all"
+
+inherit autotools autotools-multilib eutils
+
+DESCRIPTION="A unit test framework for C"
+HOMEPAGE="http://sourceforge.net/projects/check/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs subunit"
+
+DEPEND="subunit? ( dev-python/subunit )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-0.9.10-AM_PATH_CHECK.patch
+
+	sed -i -e '/^docdir =/d' {.,doc}/Makefile.am || die
+
+	# fix out-of-sourcedir build having inconsistent check.h files, for
+	# example breaks USE=subunit.
+	rm src/check.h || die
+
+	# Fix automake warnings being treated as errors, bug #420373
+	sed -i -e s/-Werror// configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-dependency-tracking
+		$(use_enable subunit)
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+	)
+	autotools-multilib_src_configure
+}
+
+src_install() {
+	autotools-multilib_src_install
+	dodoc AUTHORS *ChangeLog* NEWS README THANKS TODO
+
+	rm -f "${ED}"/usr/share/doc/${PF}/COPYING* || die
+}