Minor version bump. Set subslot to match SONAME.

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 81 insertions, 1 deletions

diff --git a/dev-libs/ucommon/ChangeLog b/dev-libs/ucommon/ChangeLog
index e983df99a7ea..5f32fc3c9678 100644
--- a/dev-libs/ucommon/ChangeLog
+++ b/dev-libs/ucommon/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/ucommon
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/ucommon/ChangeLog,v 1.20 2014/06/27 08:46:59 maksbotan Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ucommon/ChangeLog,v 1.21 2014/09/13 14:15:31 mgorny Exp $
+
+*ucommon-6.1.10 (13 Sep 2014)
+
+  13 Sep 2014; Michał Górny <mgorny@gentoo.org> +ucommon-6.1.10.ebuild:
+  Minor version bump. Set subslot to match SONAME.
 
 *ucommon-6.1.8 (27 Jun 2014)
 
diff --git a/dev-libs/ucommon/ucommon-6.1.10.ebuild b/dev-libs/ucommon/ucommon-6.1.10.ebuild
new file mode 100644
index 000000000000..f44abbcfca85
--- /dev/null
+++ b/dev-libs/ucommon/ucommon-6.1.10.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ucommon/ucommon-6.1.10.ebuild,v 1.1 2014/09/13 14:15:31 mgorny Exp $
+
+EAPI="5"
+
+AUTOTOOLS_AUTORECONF=1
+
+inherit autotools-utils eutils
+
+DESCRIPTION="Portable C++ runtime for threads and sockets"
+HOMEPAGE="http://www.gnu.org/software/commoncpp"
+SRC_URI="mirror://gnu/commoncpp/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/6"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE="doc static-libs socks +cxx debug ssl gnutls"
+
+RDEPEND="
+	ssl? (
+		!gnutls? ( dev-libs/openssl:0= )
+		gnutls? (
+			net-libs/gnutls:0=
+			dev-libs/libgcrypt:0=
+		)
+	)"
+
+DEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	${RDEPEND}"
+
+DOCS=(README NEWS SUPPORT ChangeLog AUTHORS)
+PATCHES=( "${FILESDIR}"/6.1/disable_rtf_gen_doxy.patch
+		  "${FILESDIR}"/6.1/install_gcrypt.m4_file.patch
+		  "${FILESDIR}"/6.1/gcrypt_autotools.patch )
+
+#AUTOTOOLS_IN_SOURCE_BUILD=1
+
+src_prepare() {
+	# Aclocal 1.13 deprecated error BGO #467674
+	sed -e 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' -i configure.ac || die
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	if use ssl; then
+		myconf+=" --with-sslstack=$(usex gnutls gnu ssl) "
+	else
+		myconf+=" --with-sslstack=nossl ";
+	fi
+
+	local myeconfargs=(
+		$(use_enable  socks)
+		$(use_enable  cxx stdcpp)
+		${myconf}
+		--enable-atomics
+		--with-pkg-config
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	use doc && autotools-utils_src_compile doxy
+}
+
+src_install() {
+	autotools-utils_src_install
+	if use doc; then
+		dohtml doc/html/*
+	fi
+}