version bump

(Portage version: 2.2.11-r1/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

2 files changed, 70 insertions, 1 deletions

diff --git a/dev-libs/mongo-c-driver/ChangeLog b/dev-libs/mongo-c-driver/ChangeLog
index 6e325535c23d..a551ef5cd27a 100644
--- a/dev-libs/mongo-c-driver/ChangeLog
+++ b/dev-libs/mongo-c-driver/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/mongo-c-driver
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog,v 1.16 2014/08/13 09:28:50 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog,v 1.17 2014/08/19 07:48:18 ultrabug Exp $
+
+*mongo-c-driver-0.98.2 (19 Aug 2014)
+
+  19 Aug 2014; Ultrabug <ultrabug@gentoo.org> +mongo-c-driver-0.98.2.ebuild:
+  version bump
 
   13 Aug 2014; Agostino Sarubbo <ago@gentoo.org> mongo-c-driver-0.7.1-r1.ebuild:
   Stable for ppc, wrt bug #503410
diff --git a/dev-libs/mongo-c-driver/mongo-c-driver-0.98.2.ebuild b/dev-libs/mongo-c-driver/mongo-c-driver-0.98.2.ebuild
new file mode 100644
index 000000000000..551677798d82
--- /dev/null
+++ b/dev-libs/mongo-c-driver/mongo-c-driver-0.98.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/mongo-c-driver-0.98.2.ebuild,v 1.1 2014/08/19 07:48:18 ultrabug Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="A high-performance MongoDB driver for C"
+HOMEPAGE="https://github.com/mongodb/mongo-c-driver"
+SRC_URI="https://github.com/mongodb/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="debug examples sasl ssl static-libs test"
+
+RDEPEND=">=dev-libs/libbson-0.98.0
+	sasl? ( dev-libs/cyrus-sasl )
+	ssl? ( dev-libs/openssl )"
+DEPEND="${RDEPEND}
+	test? ( dev-db/mongodb )"
+
+DOCS=( NEWS README.rst TUTORIAL.md )
+
+src_prepare() {
+	# https://github.com/mongodb/mongo-c-driver/issues/54
+	sed -i -e "s/PTHREAD_LIBS/PTHREAD_CFLAGS/g" src/Makefile.am \
+		tests/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf --disable-hardening \
+		--disable-optimizations \
+		--disable-examples \
+		$(use_enable sasl) \
+		$(use_enable ssl) \
+		$(use_enable debug) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	doman doc/*.3
+
+	use static-libs || find "${D}" -name '*.la' -delete
+
+	if use examples; then
+		insinto /usr/share/${PF}/examples
+		doins -r examples/*.c examples/aggregation examples/bulk
+	fi
+}
+
+src_test() {
+	# Avoid allocating too much disk space by using server.smallFiles = 1
+	echo -e "storage:\n    smallFiles: true" > "${T}/mongod.conf"
+	local PORT=27099
+	mongod --port ${PORT} --bind_ip 127.0.0.1 --nounixsocket --fork \
+		-f "${T}/mongod.conf" --dbpath="${T}" \
+		--logpath="${T}/mongod.log" || die
+	MONGOC_TEST_HOST="127.0.0.1:${PORT}" emake test
+	kill `cat "${T}/mongod.lock"`
+}