version bump

(Portage version: 2.1.10.4/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/dev-libs/cyrus-imap-dev/ChangeLog b/dev-libs/cyrus-imap-dev/ChangeLog
index dcd01b672c1d..1093a5b61df5 100644
--- a/dev-libs/cyrus-imap-dev/ChangeLog
+++ b/dev-libs/cyrus-imap-dev/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/cyrus-imap-dev
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyrus-imap-dev/ChangeLog,v 1.66 2011/06/22 11:03:09 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyrus-imap-dev/ChangeLog,v 1.67 2011/07/06 14:44:56 eras Exp $
+
+*cyrus-imap-dev-2.4.10 (06 Jul 2011)
+
+  06 Jul 2011; Eray Aslan <eras@gentoo.org> +cyrus-imap-dev-2.4.10.ebuild:
+  version bump
 
 *cyrus-imap-dev-2.4.9 (22 Jun 2011)
 
diff --git a/dev-libs/cyrus-imap-dev/cyrus-imap-dev-2.4.10.ebuild b/dev-libs/cyrus-imap-dev/cyrus-imap-dev-2.4.10.ebuild
new file mode 100644
index 000000000000..949527c71124
--- /dev/null
+++ b/dev-libs/cyrus-imap-dev/cyrus-imap-dev-2.4.10.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyrus-imap-dev/cyrus-imap-dev-2.4.10.ebuild,v 1.1 2011/07/06 14:44:56 eras Exp $
+
+EAPI=4
+inherit eutils db-use multilib
+
+MY_PV="${PV/_/}"
+
+DESCRIPTION="Developer support for the Cyrus IMAP Server."
+HOMEPAGE="http://asg.web.cmu.edu/cyrus/imapd/"
+SRC_URI="ftp://ftp.andrew.cmu.edu/pub/cyrus-mail/cyrus-imapd-${MY_PV}.tar.gz"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="afs berkdb kerberos snmp ssl tcpd"
+
+RDEPEND=">=dev-libs/cyrus-sasl-2.1.13
+	afs? ( net-fs/openafs )
+	berkdb? ( >=sys-libs/db-3.2 )
+	kerberos? ( virtual/krb5 )
+	snmp? ( net-analyzer/net-snmp )
+	ssl? ( >=dev-libs/openssl-0.9.6 )
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )"
+
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/cyrus-imapd-${MY_PV}"
+
+src_configure() {
+	local myconf
+	if use afs ; then
+		myconf=" --with-afs-libdir=/usr/$(get_libdir)"
+		myconf+=" --with-afs-incdir=/usr/include/afs"
+	fi
+	if use berkdb ; then
+		myconf+="--with-bdb-incdir=$(db_includedir)"
+	fi
+
+	econf \
+		--enable-murder \
+		--enable-netscapehack \
+		--enable-idled \
+		--with-cyrus-group=mail \
+		--with-com_err=yes \
+		--without-perl \
+		--without-krb \
+		--without-krbdes \
+		$(use_enable afs) \
+		$(use_enable afs krb5afspts) \
+		$(use_with berkdb bdb) \
+		$(use_with ssl openssl) \
+		$(use_with snmp) \
+		$(use_with tcpd libwrap) \
+		$(use_enable kerberos gssapi) \
+		${myconf}
+}
+
+src_compile() {
+	emake -C "${S}/lib" all
+}
+
+src_install() {
+	dodir /usr/include/cyrus
+
+	emake -C "${S}/lib" DESTDIR="${D}" install
+	dodoc README*
+}