Revision bump: EAPI 5, respect LDFLAGS, some cosmetic changes, drop unused inherit of multilib eclass

(Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

2 files changed, 74 insertions, 2 deletions

diff --git a/dev-libs/blitz/ChangeLog b/dev-libs/blitz/ChangeLog
index d2058f28ff44..76e5213415c2 100644
--- a/dev-libs/blitz/ChangeLog
+++ b/dev-libs/blitz/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/blitz
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/blitz/ChangeLog,v 1.46 2012/11/13 06:27:36 bicatali Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/blitz/ChangeLog,v 1.47 2013/08/01 18:30:06 pinkbyte Exp $
+
+*blitz-0.10-r1 (01 Aug 2013)
+
+  01 Aug 2013; Sergey Popov <pinkbyte@gentoo.org> +blitz-0.10-r1.ebuild:
+  Revision bump: EAPI 5, respect LDFLAGS, some cosmetic changes, drop unused
+  inherit of multilib eclass
 
   13 Nov 2012; Sébastien Fabbro <bicatali@gentoo.org> blitz-0.10.ebuild:
   Split doc building and compiling, resolving bug #442504
diff --git a/dev-libs/blitz/blitz-0.10-r1.ebuild b/dev-libs/blitz/blitz-0.10-r1.ebuild
new file mode 100644
index 000000000000..6986c0ee1837
--- /dev/null
+++ b/dev-libs/blitz/blitz-0.10-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/blitz/blitz-0.10-r1.ebuild,v 1.1 2013/08/01 18:30:06 pinkbyte Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+inherit autotools-utils
+
+DESCRIPTION="High-performance C++ numeric library"
+HOMEPAGE="http://blitz.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-3 Artistic-2 BSD )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~ppc-macos ~x86-linux ~x86-macos"
+
+IUSE="boost debug doc examples static-libs"
+
+RDEPEND="boost? ( >=dev-libs/boost-1.40 )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen[dot] )"
+
+PATCHES=(
+	"${FILESDIR}/${P}-docs.patch"
+	"${FILESDIR}/${P}-gcc47.patch"
+	"${FILESDIR}/${P}-set-default-arg-value.patch"
+)
+
+src_configure() {
+	# blas / fortran only needed for benchmarks
+	use doc && doxygen -u doc/doxygen/Doxyfile.in
+	local myeconfargs=(
+		--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
+		--enable-shared
+		--disable-cxx-flags-preset
+		--disable-fortran
+		--without-blas
+		$(use_enable boost serialization)
+		$(use_enable debug)
+		$(use_enable doc doxygen)
+		$(use_enable doc html-docs)
+		$(use_with boost boost "${EPREFIX}/usr")
+		$(use_with boost boost-serialization)
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile LDFLAGS="${LDFLAGS}" lib
+	use doc && autotools-utils_src_compile info html pdf
+}
+
+src_test() {
+	pushd ${AUTOTOOLS_BUILD_DIR} > /dev/null
+	emake check-testsuite check-examples
+	popd > /dev/null
+}
+
+src_install () {
+	autotools-utils_src_install $(use doc && echo install-html install-pdf)
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.{cpp,f}
+	fi
+}