Version Bump, #347561; Fix for libXft recognition, #347569

(Portage version: 2.2.0_alpha7/cvs/Linux x86_64)

9 files changed, 129 insertions, 238 deletions

diff --git a/dev-lang/tk/ChangeLog b/dev-lang/tk/ChangeLog
index 56818c7c5fa9..3c8e999c003e 100644
--- a/dev-lang/tk/ChangeLog
+++ b/dev-lang/tk/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-lang/tk
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.141 2010/10/24 15:32:37 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.142 2010/12/06 17:16:55 jlec Exp $
+
+*tk-8.5.9 (06 Dec 2010)
+
+  06 Dec 2010; Justin Lecher <jlec@gentoo.org> -tk-8.4.15-r1.ebuild,
+  tk-8.4.18.ebuild, tk-8.4.18-r1.ebuild, tk-8.4.19-r1.ebuild, tk-8.5.7.ebuild,
+  -tk-8.5.8.ebuild, tk-8.5.8-r1.ebuild, +tk-8.5.9.ebuild:
+  Version Bump, #347561; Fix for libXft recognition, #347569
 
   24 Oct 2010; Brent Baude <ranger@gentoo.org> tk-8.5.8-r1.ebuild:
   Marking tk-8.5.8-r1 ppc for bug 332415
diff --git a/dev-lang/tk/tk-8.4.15-r1.ebuild b/dev-lang/tk/tk-8.4.15-r1.ebuild
deleted file mode 100644
index b7307704797e..000000000000
--- a/dev-lang/tk/tk-8.4.15-r1.ebuild
+++ /dev/null
@@ -1,117 +0,0 @@
-# Copyright 1999-2008 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.15-r1.ebuild,v 1.12 2010/06/16 00:10:30 mr_bones_ Exp $
-
-inherit autotools eutils multilib toolchain-funcs
-
-DESCRIPTION="Tk Widget Set"
-HOMEPAGE="http://dev.scriptics.com/software/tcltk/"
-SRC_URI="mirror://sourceforge/tcl/${PN}${PV}-src.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd"
-IUSE="debug threads"
-
-RDEPEND="x11-libs/libX11
-	~dev-lang/tcl-${PV}"
-DEPEND="${RDEPEND}
-	x11-libs/libXt
-	x11-proto/xproto"
-
-S=${WORKDIR}/${PN}${PV}
-
-pkg_setup() {
-	if use threads ; then
-		ewarn ""
-		ewarn "PLEASE NOTE: You are compiling ${P} with"
-		ewarn "threading enabled."
-		ewarn "Threading is not supported by all applications"
-		ewarn "that compile against tcl. You use threading at"
-		ewarn "your own discretion."
-		ewarn ""
-		epause 5
-	fi
-}
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}"/remove-control-v-8.4.9.diff
-	epatch "${FILESDIR}"/${PN}-8.4.9-man.patch
-	epatch "${FILESDIR}"/${PN}-8.4.11-multilib.patch
-
-	# Bug 125971
-	epatch "${FILESDIR}"/${P}-tclm4-soname.patch
-
-	# Bug 192539
-	epatch "${FILESDIR}"/${PN}-CVE-2007-4851.patch
-
-	local d
-	for d in */configure ; do
-		cd "${S}"/${d%%/*}
-		EPATCH_SINGLE_MSG="Patching nls cruft in ${d}" \
-		epatch "${FILESDIR}"/tk-configure-LANG.patch
-	done
-
-	cd "${S}"/unix
-	eautoreconf
-}
-
-src_compile() {
-	tc-export CC
-	cd "${S}"/unix
-
-	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
-
-	econf \
-		--with-tcl=/usr/${mylibdir} \
-		$(use_enable threads) \
-		$(use_enable debug symbols) || die
-
-	emake || die
-}
-
-src_install() {
-	#short version number
-	local v1
-	v1=${PV%.*}
-
-	cd "${S}"/unix
-	make DESTDIR="${D}" install || die
-
-	# fix the tkConfig.sh to eliminate refs to the build directory
-	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
-	sed -i \
-		-e "s,^\(TK_BUILD_LIB_SPEC='-L\)${S}/unix,\1/usr/${mylibdir}," \
-		-e "s,^\(TK_SRC_DIR='\)${S}',\1/usr/${mylibdir}/tk${v1}/include'," \
-		-e "s,^\(TK_BUILD_STUB_LIB_SPEC='-L\)${S}/unix,\1/usr/${mylibdir}," \
-		-e "s,^\(TK_BUILD_STUB_LIB_PATH='\)${S}/unix,\1/usr/${mylibdir}," \
-		-e "s,^\(TK_CC_SEARCH_FLAGS='.*\)',\1:/usr/${mylibdir}'," \
-		-e "s,^\(TK_LD_SEARCH_FLAGS='.*\)',\1:/usr/${mylibdir}'," \
-		"${D}"/usr/${mylibdir}/tkConfig.sh || die
-
-	# install private headers
-	insinto /usr/${mylibdir}/tk${v1}/include/unix
-	doins "${S}"/unix/*.h || die
-	insinto /usr/${mylibdir}/tk${v1}/include/generic
-	doins "${S}"/generic/*.h || die
-	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tk.h
-	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tkDecls.h
-	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tkPlatDecls.h
-
-	# install symlink for libraries
-	#dosym libtk${v1}.a /usr/${mylibdir}/libtk.a
-	if use debug ; then
-		dosym libtk${v1}g.so /usr/${mylibdir}/libtk${v1}.so
-		dosym libtkstub${v1}g.a /usr/${mylibdir}/libtkstub${v1}.a
-		dosym ../tk${v1}g/pkgIndex.tcl /usr/${mylibdir}/tk${v1}/pkgIndex.tcl
-	fi
-	dosym libtk${v1}.so /usr/${mylibdir}/libtk.so
-	dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a
-
-	dosym wish${v1} /usr/bin/wish
-
-	cd "${S}"
-	dodoc ChangeLog README changes license.terms
-}
diff --git a/dev-lang/tk/tk-8.4.18-r1.ebuild b/dev-lang/tk/tk-8.4.18-r1.ebuild
index 34229bd67b93..e2faba823d36 100644
--- a/dev-lang/tk/tk-8.4.18-r1.ebuild
+++ b/dev-lang/tk/tk-8.4.18-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.18-r1.ebuild,v 1.9 2010/06/16 00:10:30 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.18-r1.ebuild,v 1.10 2010/12/06 17:16:55 jlec Exp $
 
 inherit autotools eutils multilib toolchain-funcs
 
@@ -67,7 +67,7 @@ src_compile() {
 	econf \
 		--with-tcl=/usr/${mylibdir} \
 		$(use_enable threads) \
-		$(use_enable debug symbols) || die
+		$(use_enable debug symbols)
 
 	emake || die
 }
diff --git a/dev-lang/tk/tk-8.4.18.ebuild b/dev-lang/tk/tk-8.4.18.ebuild
index d08def86ca28..9c8d013a1b91 100644
--- a/dev-lang/tk/tk-8.4.18.ebuild
+++ b/dev-lang/tk/tk-8.4.18.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.18.ebuild,v 1.10 2010/06/16 00:10:30 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.18.ebuild,v 1.11 2010/12/06 17:16:55 jlec Exp $
 
 inherit autotools eutils multilib toolchain-funcs
 
@@ -64,7 +64,7 @@ src_compile() {
 	econf \
 		--with-tcl=/usr/${mylibdir} \
 		$(use_enable threads) \
-		$(use_enable debug symbols) || die
+		$(use_enable debug symbols)
 
 	emake || die
 }
diff --git a/dev-lang/tk/tk-8.4.19-r1.ebuild b/dev-lang/tk/tk-8.4.19-r1.ebuild
index 4eeaefa01f3d..925db72c7ae5 100644
--- a/dev-lang/tk/tk-8.4.19-r1.ebuild
+++ b/dev-lang/tk/tk-8.4.19-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.19-r1.ebuild,v 1.4 2010/06/16 00:10:30 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.19-r1.ebuild,v 1.5 2010/12/06 17:16:55 jlec Exp $
 
 inherit autotools eutils multilib toolchain-funcs
 
@@ -67,7 +67,7 @@ src_compile() {
 	econf \
 		--with-tcl=/usr/${mylibdir} \
 		$(use_enable threads) \
-		$(use_enable debug symbols) || die
+		$(use_enable debug symbols)
 
 	emake || die
 }
diff --git a/dev-lang/tk/tk-8.5.7.ebuild b/dev-lang/tk/tk-8.5.7.ebuild
index ee25373ca451..7e2affb6f537 100644
--- a/dev-lang/tk/tk-8.5.7.ebuild
+++ b/dev-lang/tk/tk-8.5.7.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.7.ebuild,v 1.11 2010/06/16 00:10:30 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.7.ebuild,v 1.12 2010/12/06 17:16:55 jlec Exp $
 
 inherit autotools eutils multilib toolchain-funcs
 
@@ -58,7 +58,7 @@ src_compile() {
 		--with-tcl=/usr/${mylibdir} \
 		$(use_enable threads) \
 		$(use_enable truetype xft) \
-		$(use_enable debug symbols) || die
+		$(use_enable debug symbols)
 
 	emake || die
 }
diff --git a/dev-lang/tk/tk-8.5.8-r1.ebuild b/dev-lang/tk/tk-8.5.8-r1.ebuild
index 37bce567a0a1..f52050b4d860 100644
--- a/dev-lang/tk/tk-8.5.8-r1.ebuild
+++ b/dev-lang/tk/tk-8.5.8-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.8-r1.ebuild,v 1.9 2010/10/24 15:32:37 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.8-r1.ebuild,v 1.10 2010/12/06 17:16:55 jlec Exp $
 
 EAPI="3"
 
@@ -47,7 +47,7 @@ src_configure() {
 	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
 
 	econf \
-		--with-tcl="${EPREFIX}"/usr/${mylibdir} \
+		--with-tcl="${EPREFIX}/usr/${mylibdir}" \
 		$(use_enable threads) \
 		$(use_enable aqua) \
 		$(use_enable truetype xft) \
diff --git a/dev-lang/tk/tk-8.5.8.ebuild b/dev-lang/tk/tk-8.5.8.ebuild
deleted file mode 100644
index 06b2347e384c..000000000000
--- a/dev-lang/tk/tk-8.5.8.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.8.ebuild,v 1.3 2010/06/16 00:10:30 mr_bones_ Exp $
-
-inherit autotools eutils multilib toolchain-funcs
-
-MY_P="${PN}${PV/_beta/b}"
-DESCRIPTION="Tk Widget Set"
-HOMEPAGE="http://www.tcl.tk/"
-SRC_URI="mirror://sourceforge/tcl/${MY_P}-src.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
-IUSE="debug threads truetype"
-
-RDEPEND="x11-libs/libX11
-	~dev-lang/tcl-${PV}"
-DEPEND="${RDEPEND}
-	truetype? ( x11-libs/libXft )
-	x11-libs/libXt
-	x11-proto/xproto"
-
-S="${WORKDIR}/${MY_P}"
-
-pkg_setup() {
-	if use threads ; then
-		ewarn ""
-		ewarn "PLEASE NOTE: You are compiling ${P} with"
-		ewarn "threading enabled."
-		ewarn "Threading is not supported by all applications"
-		ewarn "that compile against tcl. You use threading at"
-		ewarn "your own discretion."
-		ewarn ""
-		epause 5
-	fi
-}
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}"/${PN}-8.4.11-multilib.patch
-
-	# Bug 125971
-	epatch "${FILESDIR}"/${PN}-8.5_alpha6-tclm4-soname.patch
-
-	cd "${S}"/unix
-	eautoreconf
-}
-
-src_compile() {
-	tc-export CC
-	cd "${S}"/unix
-
-	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
-
-	econf \
-		--with-tcl=/usr/${mylibdir} \
-		$(use_enable threads) \
-		$(use_enable truetype xft) \
-		$(use_enable debug symbols) || die
-
-	emake || die
-}
-
-src_install() {
-	#short version number
-	local v1
-	v1=${PV%.*}
-
-	cd "${S}"/unix
-	S= emake DESTDIR="${D}" install || die
-
-	# normalize $S path, bug #280766 (pkgcore)
-	local nS="$(cd "${S}"; pwd)"
-
-	# fix the tkConfig.sh to eliminate refs to the build directory
-	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
-	sed -i \
-		-e "s,^\(TK_BUILD_LIB_SPEC='-L\)${nS}/unix,\1/usr/${mylibdir}," \
-		-e "s,^\(TK_SRC_DIR='\)${nS}',\1/usr/${mylibdir}/tk${v1}/include'," \
-		-e "s,^\(TK_BUILD_STUB_LIB_SPEC='-L\)${nS}/unix,\1/usr/${mylibdir}," \
-		-e "s,^\(TK_BUILD_STUB_LIB_PATH='\)${nS}/unix,\1/usr/${mylibdir}," \
-		-e "s,^\(TK_CC_SEARCH_FLAGS='.*\)',\1:/usr/${mylibdir}'," \
-		-e "s,^\(TK_LD_SEARCH_FLAGS='.*\)',\1:/usr/${mylibdir}'," \
-		"${D}"/usr/${mylibdir}/tkConfig.sh || die
-
-	# install private headers
-	insinto /usr/${mylibdir}/tk${v1}/include/unix
-	doins "${S}"/unix/*.h || die
-	insinto /usr/${mylibdir}/tk${v1}/include/generic
-	doins "${S}"/generic/*.h || die
-	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tk.h
-	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tkDecls.h
-	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tkPlatDecls.h
-
-	# install symlink for libraries
-	#dosym libtk${v1}.a /usr/${mylibdir}/libtk.a
-	dosym libtk${v1}.so /usr/${mylibdir}/libtk.so
-	dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a
-
-	dosym wish${v1} /usr/bin/wish
-
-	cd "${S}"
-	dodoc ChangeLog* README changes
-}
diff --git a/dev-lang/tk/tk-8.5.9.ebuild b/dev-lang/tk/tk-8.5.9.ebuild
new file mode 100644
index 000000000000..dc2c32f563d4
--- /dev/null
+++ b/dev-lang/tk/tk-8.5.9.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.9.ebuild,v 1.1 2010/12/06 17:16:55 jlec Exp $
+
+EAPI="3"
+
+inherit autotools eutils multilib toolchain-funcs prefix
+
+MY_P="${PN}${PV/_beta/b}"
+
+DESCRIPTION="Tk Widget Set"
+HOMEPAGE="http://www.tcl.tk/"
+SRC_URI="mirror://sourceforge/tcl/${MY_P}-src.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug threads truetype aqua xscreensaver"
+
+RDEPEND="
+	!aqua? (
+		x11-libs/libX11
+		x11-libs/libXt
+		truetype? ( x11-libs/libXft )
+		xscreensaver? ( x11-libs/libXScrnSaver ) )
+	~dev-lang/tcl-${PV}"
+DEPEND="${RDEPEND}
+	!aqua? ( x11-proto/xproto )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-8.4.11-multilib.patch
+
+	epatch "${FILESDIR}"/${PN}-8.4.15-aqua.patch
+	eprefixify unix/Makefile.in
+
+	# Bug 125971
+	epatch "${FILESDIR}"/${PN}-8.5_alpha6-tclm4-soname.patch
+
+	cd "${S}"/unix
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+	cd "${S}"/unix
+
+	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
+
+	econf \
+		--with-tcl="${EPREFIX}/usr/${mylibdir}" \
+		$(use_enable threads) \
+		$(use_enable aqua) \
+		$(use_enable truetype xft) \
+		$(use_enable xscreensaver xss) \
+		$(use_enable debug symbols)
+}
+
+src_compile() {
+	cd "${S}"/unix
+	emake || die
+}
+
+src_install() {
+	#short version number
+	local v1
+	v1=${PV%.*}
+
+	cd "${S}"/unix
+	S= emake DESTDIR="${D}" install || die
+
+	# normalize $S path, bug #280766 (pkgcore)
+	local nS="$(cd "${S}"; pwd)"
+
+	# fix the tkConfig.sh to eliminate refs to the build directory
+	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
+	sed -i \
+		-e "s,^\(TK_BUILD_LIB_SPEC='-L\)${nS}/unix,\1${EPREFIX}/usr/${mylibdir}," \
+		-e "s,^\(TK_SRC_DIR='\)${nS}',\1${EPREFIX}/usr/${mylibdir}/tk${v1}/include'," \
+		-e "s,^\(TK_BUILD_STUB_LIB_SPEC='-L\)${nS}/unix,\1${EPREFIX}/usr/${mylibdir}," \
+		-e "s,^\(TK_BUILD_STUB_LIB_PATH='\)${nS}/unix,\1${EPREFIX}/usr/${mylibdir}," \
+		"${ED}"/usr/${mylibdir}/tkConfig.sh || die
+	[[ ${CHOST} != *-darwin* ]] && sed -i \
+		-e "s,^\(TK_CC_SEARCH_FLAGS='.*\)',\1:${EPREFIX}/usr/${mylibdir}'," \
+		-e "s,^\(TK_LD_SEARCH_FLAGS='.*\)',\1:${EPREFIX}/usr/${mylibdir}'," \
+		"${ED}"/usr/${mylibdir}/tkConfig.sh || die
+
+	# install private headers
+	insinto /usr/${mylibdir}/tk${v1}/include/unix
+	doins "${S}"/unix/*.h || die
+	insinto /usr/${mylibdir}/tk${v1}/include/generic
+	doins "${S}"/generic/*.h || die
+	rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tk.h
+	rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tkDecls.h
+	rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tkPlatDecls.h
+
+	# install symlink for libraries
+	#dosym libtk${v1}.a /usr/${mylibdir}/libtk.a
+	dosym libtk${v1}$(get_libname) /usr/${mylibdir}/libtk$(get_libname) || die
+	dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a || die
+
+	dosym wish${v1} /usr/bin/wish || die
+
+	cd "${S}"
+	dodoc ChangeLog* README changes || die
+}