EAPI bump, install examples and some QA

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 77C501ED)

2 files changed, 66 insertions, 1 deletions

diff --git a/dev-java/jgoodies-looks/ChangeLog b/dev-java/jgoodies-looks/ChangeLog
index 65f9d96e2b7f..e2b1ad1747e7 100644
--- a/dev-java/jgoodies-looks/ChangeLog
+++ b/dev-java/jgoodies-looks/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/jgoodies-looks
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/jgoodies-looks/ChangeLog,v 1.44 2014/09/07 16:13:25 ercpe Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jgoodies-looks/ChangeLog,v 1.45 2014/09/07 16:22:14 ercpe Exp $
+
+*jgoodies-looks-2.3.1-r1 (07 Sep 2014)
+
+  07 Sep 2014; Johann Schmitz <ercpe@gentoo.org>
+  +jgoodies-looks-2.3.1-r1.ebuild:
+  EAPI bump, install examples and some QA
 
 *jgoodies-looks-1.2.2-r2 (07 Sep 2014)
 
diff --git a/dev-java/jgoodies-looks/jgoodies-looks-2.3.1-r1.ebuild b/dev-java/jgoodies-looks/jgoodies-looks-2.3.1-r1.ebuild
new file mode 100644
index 000000000000..896aa592fc21
--- /dev/null
+++ b/dev-java/jgoodies-looks/jgoodies-looks-2.3.1-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jgoodies-looks/jgoodies-looks-2.3.1-r1.ebuild,v 1.1 2014/09/07 16:22:14 ercpe Exp $
+
+EAPI=5
+
+JAVA_PKG_IUSE="doc source examples"
+
+inherit eutils java-pkg-2 java-ant-2
+
+MY_PN="looks"
+MY_PV="${PV//./_}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="JGoodies Looks Library"
+HOMEPAGE="http://www.jgoodies.com/"
+SRC_URI="http://www.jgoodies.com/download/libraries/${MY_PN}/${MY_P}.zip"
+
+LICENSE="BSD"
+SLOT="2.0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE=""
+
+DEPEND=">=virtual/jdk-1.4
+	app-arch/unzip"
+RDEPEND=">=virtual/jre-1.4"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+# bug #150970
+EANT_FILTER_COMPILER="jikes"
+# jar target fails unless we make descriptors.dir an existing directory
+# update: it's where it looks for all.txt file
+EANT_EXTRA_ARGS="-Ddescriptors.dir=\"${S}\""
+
+EANT_BUILD_TARGET="jar-all"
+
+java_prepare() {
+	# remove the bootclasspath brokedness, make building demo optional
+	epatch "${FILESDIR}/${PN}-2.0.4-build.xml.patch"
+
+	# unzip the look&feel settings from bundled jar before we delete it
+	unzip -j looks-${PV}.jar META-INF/services/javax.swing.LookAndFeel \
+		|| die "unzip of javax.swing.LookAndFeel failed"
+	# and rename it to what build.xml expects
+	mv javax.swing.LookAndFeel all.txt
+
+	find -name "*.jar" -delete || die
+}
+
+src_install() {
+	java-pkg_dojar build/looks.jar
+
+	dodoc RELEASE-NOTES.txt || die
+	dohtml README.html || die
+	use doc && java-pkg_dojavadoc build/docs/api
+	use source && java-pkg_dosrc src/core/com
+	use examples && java-pkg_doexamples src/demo
+}