Add 1.4.2_p20150608 snapshot with timestamp preservation for bug 551486.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key FDE8EF85AE5719A3)

3 files changed, 70 insertions, 2 deletions

diff --git a/dev-go/go-crypto/ChangeLog b/dev-go/go-crypto/ChangeLog
index 8a29f023ba55..9c891531a9d6 100644
--- a/dev-go/go-crypto/ChangeLog
+++ b/dev-go/go-crypto/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-go/go-crypto
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-go/go-crypto/ChangeLog,v 1.5 2015/05/24 08:37:29 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-go/go-crypto/ChangeLog,v 1.6 2015/06/09 03:22:30 zmedico Exp $
+
+*go-crypto-1.4.2_p20150608 (09 Jun 2015)
+
+  09 Jun 2015; Zac Medico <zmedico@gentoo.org>
+  +go-crypto-1.4.2_p20150608.ebuild, go-crypto-9999.ebuild:
+  Add 1.4.2_p20150608 snapshot with timestamp preservation for bug 551486.
 
   24 May 2015; Zac Medico <zmedico@gentoo.org> go-crypto-1.4.2_p20150514.ebuild,
   go-crypto-9999.ebuild:
diff --git a/dev-go/go-crypto/go-crypto-1.4.2_p20150608.ebuild b/dev-go/go-crypto/go-crypto-1.4.2_p20150608.ebuild
new file mode 100644
index 000000000000..45756a9db796
--- /dev/null
+++ b/dev-go/go-crypto/go-crypto-1.4.2_p20150608.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-go/go-crypto/go-crypto-1.4.2_p20150608.ebuild,v 1.1 2015/06/09 03:22:30 zmedico Exp $
+
+EAPI=5
+
+KEYWORDS="~amd64"
+DESCRIPTION="Go supplementary cryptography libraries"
+MY_PN=${PN##*-}
+GO_PN=golang.org/x/${MY_PN}
+HOMEPAGE="https://godoc.org/${GO_PN}"
+EGIT_COMMIT="1e856cbfdf9bc25eefca75f83f25d55e35ae72e0"
+SRC_URI="https://github.com/golang/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+IUSE=""
+DEPEND=">=dev-lang/go-1.4"
+RDEPEND=""
+S="${WORKDIR}/src/${GO_PN}"
+EGIT_CHECKOUT_DIR="${S}"
+STRIP_MASK="*.a"
+
+src_unpack() {
+	default
+	mkdir -p src/${GO_PN%/*} || die
+	mv ${MY_PN}-${EGIT_COMMIT} src/${GO_PN} || die
+}
+
+src_prepare() {
+	# disable broken tests
+	sed -e 's:TestAgentForward(:_\0:' -i ssh/test/agent_unix_test.go || die
+	sed -e 's:TestRunCommandSuccess(:_\0:' \
+		-e 's:TestRunCommandStdin(:_\0:' \
+		-e 's:TestRunCommandStdinError(:_\0:' \
+		-e 's:TestRunCommandWeClosed(:_\0:' \
+		-e 's:TestFuncLargeRead(:_\0:' \
+		-e 's:TestKeyChange(:_\0:' \
+		-e 's:TestValidTerminalMode(:_\0:' \
+		-i ssh/test/session_test.go || die
+}
+
+src_compile() {
+	# Create a writable GOROOT in order to avoid sandbox violations.
+	GOROOT="${WORKDIR}/goroot"
+	cp -sR "${EPREFIX}"/usr/lib/go "${GOROOT}" || die
+	rm -rf "${GOROOT}/src/${GO_PN%/*}" \
+		"${GOROOT}/pkg/linux_${ARCH}/${GO_PN%/*}" || die
+	GOROOT="${GOROOT}" GOPATH=${WORKDIR} go install -v -x -work ${GO_PN}/... || die
+}
+
+src_test() {
+	GOROOT="${GOROOT}" GOPATH=${WORKDIR} \
+		go test -x -v ${GO_PN}/... || die $?
+}
+
+src_install() {
+	insinto /usr/lib/go
+	find "${WORKDIR}"/{pkg,src} -name '.git*' -exec rm -rf {} \; 2>/dev/null
+	insopts -m0644 -p # preserve timestamps for bug 551486
+	doins -r "${WORKDIR}"/{pkg,src}
+}
diff --git a/dev-go/go-crypto/go-crypto-9999.ebuild b/dev-go/go-crypto/go-crypto-9999.ebuild
index 26b184e1f8f5..b7c065fecb1d 100644
--- a/dev-go/go-crypto/go-crypto-9999.ebuild
+++ b/dev-go/go-crypto/go-crypto-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-go/go-crypto/go-crypto-9999.ebuild,v 1.4 2015/05/24 08:37:29 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-go/go-crypto/go-crypto-9999.ebuild,v 1.5 2015/06/09 03:22:30 zmedico Exp $
 
 EAPI=5
 inherit git-r3
@@ -49,5 +49,6 @@ src_test() {
 src_install() {
 	insinto /usr/lib/go
 	find "${WORKDIR}"/{pkg,src} -name '.git*' -exec rm -rf {} \; 2>/dev/null
+	insopts -m0644 -p # preserve timestamps for bug 551486
 	doins -r "${WORKDIR}"/{pkg,src}
 }