version bump (bug #541206)

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key 0x4FDF9CFD2FAC514E!)

2 files changed, 95 insertions, 1 deletions

diff --git a/app-text/qpdfview/ChangeLog b/app-text/qpdfview/ChangeLog
index fd0b2b4a5fb8..d55b6ecb0207 100644
--- a/app-text/qpdfview/ChangeLog
+++ b/app-text/qpdfview/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/qpdfview
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/qpdfview/ChangeLog,v 1.65 2015/02/20 08:39:29 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/qpdfview/ChangeLog,v 1.66 2015/03/05 13:37:24 yngwin Exp $
+
+*qpdfview-0.4.14 (05 Mar 2015)
+
+  05 Mar 2015; Ben de Groot <yngwin@gentoo.org> +qpdfview-0.4.14.ebuild:
+  version bump (bug #541206)
 
   20 Feb 2015; Ben de Groot <yngwin@gentoo.org> metadata.xml:
   Improve USE=fitz description (bug #540450)
diff --git a/app-text/qpdfview/qpdfview-0.4.14.ebuild b/app-text/qpdfview/qpdfview-0.4.14.ebuild
new file mode 100644
index 000000000000..53a4b3d80788
--- /dev/null
+++ b/app-text/qpdfview/qpdfview-0.4.14.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/qpdfview/qpdfview-0.4.14.ebuild,v 1.1 2015/03/05 13:37:24 yngwin Exp $
+
+EAPI=5
+
+PLOCALES="ast az be bg bs ca cs da de el en_GB eo es eu fi fr gl he hr id it kk ky lt ms my pl pt pt_BR ro ru sk sv th tr ug uk vi zh_CN"
+inherit eutils l10n multilib qmake-utils
+
+DESCRIPTION="A tabbed document viewer"
+HOMEPAGE="http://launchpad.net/qpdfview"
+SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="cups dbus djvu fitz +pdf postscript +qt4 qt5 sqlite +svg synctex"
+
+REQUIRED_USE="^^ ( qt4 qt5 )
+	?? ( fitz pdf )"
+
+RDEPEND="cups? ( net-print/cups )
+	djvu? ( app-text/djvu )
+	fitz? ( app-text/mupdf:0/1.4 )
+	postscript? ( app-text/libspectre )
+	qt4? ( >=dev-qt/qtcore-4.8.6-r1:4[iconv]
+		dev-qt/qtgui:4
+		dbus? ( dev-qt/qtdbus:4 )
+		pdf? ( app-text/poppler[qt4] )
+		sqlite? ( dev-qt/qtsql:4[sqlite] )
+		svg? ( dev-qt/qtsvg:4 ) )
+	qt5? ( dev-qt/linguist-tools:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtprintsupport:5
+		dbus? ( dev-qt/qtdbus:5 )
+		pdf? ( >=app-text/poppler-0.26.4[qt5] )
+		sqlite? ( dev-qt/qtsql:5[sqlite] )
+		svg? ( dev-qt/qtsvg:5 ) )
+	!svg? ( virtual/freedesktop-icon-theme )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( CHANGES CONTRIBUTORS README TODO )
+
+src_prepare() {
+	prepare_locale() {
+		local _lrel
+		use qt4 && _lrel="${EPREFIX}/usr/$(get_libdir)/qt4/bin/lrelease"
+		use qt5 && _lrel="${EPREFIX}/usr/$(get_libdir)/qt5/bin/lrelease"
+		${_lrel} "translations/${PN}_${1}.ts" || die "preparing ${1} locale failed"
+	}
+
+	rm_help() {
+		rm -f "miscellaneous/help_${1}.html" || die "removing extraneous help files failed"
+	}
+
+	l10n_find_plocales_changes translations "${PN}_" '.ts'
+	l10n_for_each_locale_do prepare_locale
+	l10n_for_each_disabled_locale_do rm_help
+
+	# adapt for prefix
+	sed -i -e "s:/usr:${EPREFIX}/usr:g" qpdfview.pri || die
+}
+
+src_configure() {
+	local config i
+	for i in cups dbus pdf djvu svg synctex; do
+		if ! use ${i}; then
+			config+=" without_${i}"
+		fi
+	done
+
+	use fitz && config+=" with_fitz"
+	use postscript || config+=" without_ps"
+	use sqlite || config+=" without_sql"
+
+	if use qt4; then
+		eqmake4 CONFIG+="${config}" PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}"
+	else
+		eqmake5 CONFIG+="${config}" PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}" qpdfview.pro
+	fi
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}