Version bump.

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

2 files changed, 97 insertions, 1 deletions

diff --git a/app-text/kchmviewer/ChangeLog b/app-text/kchmviewer/ChangeLog
index df907fdb3fef..3883faff0cee 100644
--- a/app-text/kchmviewer/ChangeLog
+++ b/app-text/kchmviewer/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/kchmviewer
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/kchmviewer/ChangeLog,v 1.58 2014/08/10 18:25:14 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/kchmviewer/ChangeLog,v 1.59 2014/10/17 16:48:02 kensington Exp $
+
+*kchmviewer-7.1 (17 Oct 2014)
+
+  17 Oct 2014; Michael Palimaka <kensington@gentoo.org> +kchmviewer-7.1.ebuild:
+  Version bump.
 
   10 Aug 2014; Sergei Trofimovich <slyfox@gentoo.org> kchmviewer-6.0-r1.ebuild:
   QA: drop trailing '.' from DESCRIPTION
diff --git a/app-text/kchmviewer/kchmviewer-7.1.ebuild b/app-text/kchmviewer/kchmviewer-7.1.ebuild
new file mode 100644
index 000000000000..f8b186b19121
--- /dev/null
+++ b/app-text/kchmviewer/kchmviewer-7.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/kchmviewer/kchmviewer-7.1.ebuild,v 1.1 2014/10/17 16:48:02 kensington Exp $
+
+EAPI=5
+
+KDE_REQUIRED="optional"
+KDE_LINGUAS="cs fr hu it nl pt_BR ru sv tr uk zh_CN zh_TW"
+inherit eutils fdo-mime kde4-base qmake-utils
+
+DESCRIPTION="A feature rich chm file viewer, based on Qt"
+HOMEPAGE="http://www.kchmviewer.net/"
+SRC_URI="mirror://sourceforge/kchmviewer/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug kde"
+
+RDEPEND="
+	dev-libs/chmlib
+	dev-libs/libzip
+	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
+	dev-qt/qtgui:4
+	dev-qt/qtwebkit:4
+	kde? (
+		$(add_kdebase_dep kdelibs)
+		!kde-base/okular[chm]
+	)
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	use kde && kde4-base_pkg_setup
+}
+
+src_prepare() {
+	local lang
+	for lang in ${KDE_LINGUAS} ; do
+		if ! use linguas_${lang} ; then
+			rm po/${PN}_${lang}.po
+		fi
+	done
+}
+
+src_configure() {
+	if use kde; then
+		kde4-base_src_configure
+	else
+		eqmake4
+	fi
+}
+
+src_compile() {
+	if use kde; then
+		kde4-base_src_compile
+	else
+		default
+	fi
+}
+
+src_install() {
+	dodoc DBUS-bindings FAQ
+	doicon packages/kchmviewer.png
+
+	if use kde; then
+		kde4-base_src_install
+	else
+		dobin bin/kchmviewer
+		domenu packages/kchmviewer.desktop
+		dodoc ChangeLog README
+	fi
+
+}
+
+pkg_postinst() {
+	if use kde; then
+		kde4-base_pkg_postinst
+	else
+		fdo-mime_desktop_database_update
+	fi
+}
+
+pkg_postrm() {
+	if use kde; then
+		kde4-base_pkg_postrm
+	else
+		fdo-mime_desktop_database_update
+	fi
+}