Version bump

(Portage version: 2.1.3_rc9)

3 files changed, 133 insertions, 1 deletions

diff --git a/app-office/gnucash/ChangeLog b/app-office/gnucash/ChangeLog
index d86b39801d59..47e7db9d2f8f 100644
--- a/app-office/gnucash/ChangeLog
+++ b/app-office/gnucash/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/gnucash
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.137 2007/07/21 12:14:32 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.138 2007/07/31 13:34:54 tove Exp $
+
+*gnucash-2.2.0 (31 Jul 2007)
+
+  31 Jul 2007; Torsten Veller <tove@gentoo.org> +gnucash-2.2.0.ebuild:
+  Version bump (#174967)
 
   21 Jul 2007; Torsten Veller <tove@gentoo.org> metadata.xml,
   gnucash-2.0.5.ebuild:
diff --git a/app-office/gnucash/files/digest-gnucash-2.2.0 b/app-office/gnucash/files/digest-gnucash-2.2.0
new file mode 100644
index 000000000000..3f247ea06649
--- /dev/null
+++ b/app-office/gnucash/files/digest-gnucash-2.2.0
@@ -0,0 +1,6 @@
+MD5 6e8c1602b365d76ec19ef211857d3ece gnucash-2.2.0.tar.bz2 7055411
+RMD160 581d8ade617a13c330d25e5c6f5e85c8da47ef91 gnucash-2.2.0.tar.bz2 7055411
+SHA256 b9d246b51d0f2f38f92c2d9b20d368f954bc57925e86212a0228df8e085f0741 gnucash-2.2.0.tar.bz2 7055411
+MD5 97a29e499baca1807a3944ae3c0ad61e gnucash-docs-2.2.0.tar.gz 10023082
+RMD160 3f413e3a5e5f4f9cce2ae5e4a8a3ad1b468c2603 gnucash-docs-2.2.0.tar.gz 10023082
+SHA256 8530d00b7dbe7c06022608ce134a10206ca58558a5bb61cb83b859e74fc337b3 gnucash-docs-2.2.0.tar.gz 10023082
diff --git a/app-office/gnucash/gnucash-2.2.0.ebuild b/app-office/gnucash/gnucash-2.2.0.ebuild
new file mode 100644
index 000000000000..db94afde6b85
--- /dev/null
+++ b/app-office/gnucash/gnucash-2.2.0.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.2.0.ebuild,v 1.1 2007/07/31 13:34:54 tove Exp $
+
+inherit eutils gnome2
+
+DOC_VER="2.2.0"
+
+DESCRIPTION="A personal finance manager."
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	mirror://sourceforge/${PN}/${PN}-docs-${DOC_VER}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+
+IUSE="ofx hbci chipcard debug quotes nls"
+
+RDEPEND=">=dev-libs/glib-2.6.3
+	>=dev-scheme/guile-1.6
+	=dev-scheme/slib-3.1.1*
+	>=sys-libs/zlib-1.1.4
+	>=dev-libs/popt-1.5
+	>=x11-libs/gtk+-2.6
+	>=gnome-base/libgnomeui-2.4
+	>=gnome-base/libgnomeprint-2.10
+	>=gnome-base/libgnomeprintui-2.10
+	>=gnome-base/libglade-2.4
+	|| (
+		=gnome-extra/gtkhtml-3.12*
+		=gnome-extra/gtkhtml-3.10*
+	)
+	>=dev-libs/libxml2-2.5.10
+	>=gnome-base/gconf-2
+	>=app-text/scrollkeeper-0.3
+	>=x11-libs/goffice-0.1.0
+	gnome-extra/yelp
+	ofx? ( >=dev-libs/libofx-0.7.0 )
+	hbci? ( net-libs/aqbanking
+		chipcard? ( sys-libs/libchipcard )
+	)
+	quotes? ( dev-perl/DateManip
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/HTML-TableExtract )
+	app-text/docbook-xsl-stylesheets
+	=app-text/docbook-xml-dtd-4.1.2*
+	nls? ( dev-util/intltool )
+	media-libs/libart_lgpl
+	x11-libs/pango"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/libtool
+	>=dev-lang/swig-1.3.28"
+
+ELTCONF="--patch-only"
+
+pkg_setup() {
+	local will_die=false
+	if ! built_with_use gnome-extra/libgsf gnome ; then
+		einfo "gnome-extra/libgsf must be built with gnome use flag"
+		will_die=true
+	fi
+	if ! built_with_use x11-libs/goffice gnome ; then
+		einfo "x11-libs/goffice must be built with gnome use flag"
+		will_die=true
+	fi
+
+	if has_version =dev-scheme/guile-1.8*; then
+		local flags="deprecated regex"
+		if ! built_with_use dev-scheme/guile ${flags}; then
+			einfo "dev-scheme/guile must be built with \"${flags}\" use flags"
+			will_die=true
+		fi
+	fi
+	if ${will_die}; then
+		die "Please rebuilt the packages with the use flags above."
+	fi
+}
+
+src_compile() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable ofx) \
+		$(use_enable hbci) \
+		--disable-doxygen \
+		--enable-locale-specific-tax \
+		|| die "econf failed"
+	emake -j1 || die "emake failed"
+
+	cd "${WORKDIR}/gnucash-docs-${DOC_VER}"
+	econf || die "doc econf failed"
+	emake -j1 || die "doc emake failed"
+}
+
+src_test() {
+	GUILE_WARN_DEPRECATED=no \
+	emake -j1 check \
+	|| die "Make check failed. See above for details."
+}
+
+src_install() {
+	gnome2_src_install || die "gnome2_src_install failed"
+	dodoc AUTHORS ChangeLog* DOCUMENTERS HACKING NEWS TODO README* doc/README*
+
+	cd "${WORKDIR}/${PN}-docs-${DOC_VER}"
+	make DESTDIR="${D}" \
+		scrollkeeper_localstate_dir="${D}/var/lib/scrollkeeper" \
+		install || die "doc install failed"
+	rm -rf "${D}/var/lib/scrollkeeper"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	ewarn ""
+	ewarn "If you are using Scheduled Transactions, the data file saved by"
+	ewarn "GnuCash 2.2 is NOT backward-compatible with GnuCash 2.0."
+	ewarn "Please make a safe backup of your 2.0 data before upgrading to 2.2"
+	ewarn ""
+}