version bump

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key EB9B4AFA)

3 files changed, 93 insertions, 2 deletions

diff --git a/app-misc/vifm/ChangeLog b/app-misc/vifm/ChangeLog
index 790c86572aa4..b3f3a0a1c075 100644
--- a/app-misc/vifm/ChangeLog
+++ b/app-misc/vifm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/vifm
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/vifm/ChangeLog,v 1.30 2013/06/19 13:25:50 wired Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/vifm/ChangeLog,v 1.31 2014/01/18 00:40:31 wired Exp $
+
+*vifm-0.7.6 (18 Jan 2014)
+
+  18 Jan 2014; Alex Alexander <wired@gentoo.org> +vifm-0.7.6.ebuild,
+  metadata.xml:
+  version bump
 
   19 Jun 2013; Alex Alexander <wired@gentoo.org> vifm-0.7.5.ebuild:
   fixed test run, bug #460240
diff --git a/app-misc/vifm/metadata.xml b/app-misc/vifm/metadata.xml
index acba9d310918..8b253ac47a79 100644
--- a/app-misc/vifm/metadata.xml
+++ b/app-misc/vifm/metadata.xml
@@ -7,6 +7,7 @@
 	</maintainer>
 	<use>
 		<flag name="compatibility">Compatibility with previous versions of vifm</flag>
+		<flag name="developer">Enable features of interest to developers</flag>
 		<flag name="extended-keys">Support for extended keys (arrows, home etc)</flag>
 		<flag name="gtk">Use gtk+ to determine mimetypes</flag>
 		<flag name="magic">Use libmagic to determine mimetypes</flag>
diff --git a/app-misc/vifm/vifm-0.7.6.ebuild b/app-misc/vifm/vifm-0.7.6.ebuild
new file mode 100644
index 000000000000..ed1002a3d40c
--- /dev/null
+++ b/app-misc/vifm/vifm-0.7.6.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/vifm/vifm-0.7.6.ebuild,v 1.1 2014/01/18 00:40:31 wired Exp $
+
+EAPI=5
+inherit base vim-doc
+
+DESCRIPTION="Console file manager with vi(m)-like keybindings"
+HOMEPAGE="http://vifm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/vifm/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~s390 ~x86"
+IUSE="X developer +extended-keys gtk +magic vim vim-syntax"
+
+DEPEND="
+	>=sys-libs/ncurses-5.7-r7
+	magic? ( sys-apps/file )
+	gtk? ( x11-libs/gtk+:2 )
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="
+	${DEPEND}
+	vim? ( || ( app-editors/vim app-editors/gvim ) )
+	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
+"
+
+DOCS=( AUTHORS TODO README )
+
+src_configure() {
+	econf \
+		$(use_enable developer) \
+		$(use_enable extended-keys) \
+		$(use_with magic libmagic) \
+		$(use_with gtk) \
+		$(use_with X X11)
+}
+
+src_install() {
+	base_src_install
+
+	if use vim; then
+		local t
+		for t in doc plugin; do
+			insinto /usr/share/vim/vimfiles/"${t}"
+			doins "${S}"/data/vim/"${t}"/"${PN}".*
+		done
+	fi
+
+	if use vim-syntax; then
+		local t
+		for t in ftdetect ftplugin syntax; do
+			insinto /usr/share/vim/vimfiles/"${t}"
+			doins "${S}"/data/vim/"${t}"/"${PN}".vim
+		done
+	fi
+}
+
+src_test() {
+	emake check
+}
+
+pkg_postinst() {
+	if use vim; then
+		update_vim_helptags
+
+		if [[ -n ${REPLACING_VERSIONS} ]]; then
+			elog
+			elog "You don't need to copy or link any files for"
+			elog "  the vim plugin and documentation to work anymore."
+			elog "If you copied any vifm files to ~/.vim/ manually"
+			elog "  in earlier vifm versions, please delete them."
+		fi
+		elog
+		elog "To use vim in vifm to view the documentation"
+		elog "  edit ~/.vifm/vifmrc and set vimhelp instead of novimhelp"
+		elog
+	fi
+}
+
+pkg_postrm() {
+	use vim && update_vim_helptags
+}