Unbundle minilzo (bug #515286).

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 611FF3AA)

2 files changed, 71 insertions, 3 deletions

diff --git a/app-misc/bb/ChangeLog b/app-misc/bb/ChangeLog
index 9f56f4c47de1..be96cbe344ca 100644
--- a/app-misc/bb/ChangeLog
+++ b/app-misc/bb/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/bb
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/bb/ChangeLog,v 1.6 2012/03/18 18:20:26 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/bb/ChangeLog,v 1.7 2014/06/30 14:18:42 slyfox Exp $
+
+*bb-1.3.0_rc1-r3 (30 Jun 2014)
+
+  30 Jun 2014; Sergei Trofimovich <slyfox@gentoo.org> +bb-1.3.0_rc1-r3.ebuild:
+  Unbundle minilzo (bug #515286).
 
   18 Mar 2012; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Drop maintainer due retirement, bug 118003.
@@ -32,4 +37,3 @@
   05 Jan 2008; Markus Ullmann <jokey@gentoo.org>
   +files/bb-1.3.0_rc1-noattr.patch, +metadata.xml, +bb-1.3.0_rc1.ebuild:
   Initial import wrt bug #201908 thanks to Gokdeniz Karadag for the ebuild
-
diff --git a/app-misc/bb/bb-1.3.0_rc1-r3.ebuild b/app-misc/bb/bb-1.3.0_rc1-r3.ebuild
new file mode 100644
index 000000000000..4407d147ad8c
--- /dev/null
+++ b/app-misc/bb/bb-1.3.0_rc1-r3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/bb/bb-1.3.0_rc1-r3.ebuild,v 1.1 2014/06/30 14:18:42 slyfox Exp $
+
+EAPI=5
+
+inherit autotools eutils versionator
+
+MY_P="${PN}-$(get_version_component_range 1-2)$(get_version_component_range 4-4)"
+
+DESCRIPTION="Demonstration program for visual effects of aalib"
+HOMEPAGE="http://aa-project.sourceforge.net/"
+SRC_URI="mirror://sourceforge/aa-project/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="mikmod"
+
+DEPEND="media-libs/aalib:=
+	dev-libs/lzo:=
+	mikmod? ( media-libs/libmikmod:= )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-$(get_version_component_range 1-3)"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-noattr.patch"
+	epatch "${FILESDIR}/${P}-fix-protos.patch"
+	epatch "${FILESDIR}"/${P}-messager-overlap.patch
+	epatch "${FILESDIR}"/${P}-zbuff-fault.patch
+	epatch "${FILESDIR}"/${P}-printf-cleanup.patch
+	epatch "${FILESDIR}"/${P}-m4-stuff.patch
+
+	# unbundle lzo, #515286
+	rm -v README.LZO minilzo.{c,h} mylzo.h || die
+	sed -e 's/minilzo.c//' \
+	    -e 's/minilzo.h//' \
+	    -e 's/README.LZO//' \
+		-i Makefile.am || die
+	echo 'bb_LDADD = -llzo2' >> Makefile.am || die
+	# update code
+	sed -e 's,#include "minilzo.h",#include <lzo/lzo1x.h>,' \
+	    -e 's,int size = image,lzo_uint size = image,' \
+		-i image.c || die
+
+	# rename binary and manpage bb -> bb-aalib
+
+	mv bb.1 bb-aalib.1 || die
+	sed -e 's/bb/bb-aalib/' \
+		-i bb-aalib.1
+	sed -e 's/bin_PROGRAMS = bb/bin_PROGRAMS = bb-aalib/' \
+	    -e 's/man_MANS = bb.1/man_MANS = bb-aalib.1/'     \
+	    -e 's/bb_SOURCES/bb_aalib_SOURCES/'               \
+	    -e 's/bb_LDADD/bb_aalib_LDADD/'                   \
+		-i Makefile.am || die
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+pkg_postinst() {
+	elog "bb binary has been renamed to bb-aalib to avoid a naming conflict with sys-apps/busybox."
+}