New ebuild for a LaTeX IDE for bug #380779, thanks to Sébastien Wilmet.

(Portage version: 2.2.0_alpha80/cvs/Linux x86_64)

3 files changed, 85 insertions, 0 deletions

diff --git a/app-editors/latexila/ChangeLog b/app-editors/latexila/ChangeLog
new file mode 100644
index 000000000000..03f7bee7bae9
--- /dev/null
+++ b/app-editors/latexila/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for app-editors/latexila
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/latexila/ChangeLog,v 1.1 2011/12/17 09:06:16 tetromino Exp $
+
+*latexila-2.2.2 (17 Dec 2011)
+
+  17 Dec 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +latexila-2.2.2.ebuild, +metadata.xml:
+  New ebuild for a LaTeX IDE for bug #380779, thanks to Sébastien Wilmet.
+
diff --git a/app-editors/latexila/latexila-2.2.2.ebuild b/app-editors/latexila/latexila-2.2.2.ebuild
new file mode 100644
index 000000000000..1a6103c6fa6b
--- /dev/null
+++ b/app-editors/latexila/latexila-2.2.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/latexila/latexila-2.2.2.ebuild,v 1.1 2011/12/17 09:06:16 tetromino Exp $
+
+EAPI="4"
+CMAKE_MIN_VERSION="2.6.4"
+CMAKE_IN_SOURCE_BUILD="yes" # for gnome2.eclass compat
+GCONF_DEBUG="no"
+
+inherit cmake-utils gnome2
+
+DESCRIPTION="Integrated LaTeX environment for GNOME"
+HOMEPAGE="http://projects.gnome.org/latexila/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome +latexmk rubber"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.28:2
+	dev-libs/libgee
+	dev-libs/libunique:1
+	>=x11-libs/gtk+-2.16:2
+	>=x11-libs/gtksourceview-2.10:2.0
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libX11
+	x11-libs/pango
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+"
+RDEPEND="${COMMON_DEPEND}
+	virtual/latex-base
+	x11-themes/hicolor-icon-theme
+	latexmk? ( dev-tex/latexmk )
+	rubber? ( dev-tex/rubber )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-util/itstool
+	dev-util/pkgconfig
+	sys-devel/gettext
+"
+
+pkg_setup() {
+	DOCS="AUTHORS HACKING NEWS README TODO"
+}
+
+src_prepare() {
+	if [[ -n ${LINGUAS+set} ]]; then
+		# LINGUAS is set, let's try to respect it.
+		pushd po > /dev/null
+		local po_file
+		for po_file in *.po; do
+			has "${po_file%.po}" ${LINGUAS} || rm -v "${po_file}"
+		done
+		popd > /dev/null
+	fi
+}
+
+src_configure() {
+	local mycmakeargs="
+		$(cmake-utils_use_with gnome GNOME)
+		-DCOMPILE_SCHEMA=OFF"
+	cmake-utils_src_configure
+}
diff --git a/app-editors/latexila/metadata.xml b/app-editors/latexila/metadata.xml
new file mode 100644
index 000000000000..bba9d6cb634f
--- /dev/null
+++ b/app-editors/latexila/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>gnome</herd>
+<use>
+	<flag name="latexmk">Install <pkg>dev-tex/latexmk</pkg> (used by default
+		for the build tools)</flag>
+	<flag name="rubber">Install <pkg>dev-tex/rubber</pkg> (can be used for the
+		build tools)</flag>
+</use>
+</pkgmetadata>