Use latest from git which should be reasonable stable.

(Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

2 files changed, 64 insertions, 1 deletions

diff --git a/app-cdr/xfburn/ChangeLog b/app-cdr/xfburn/ChangeLog
index b7365498cb61..22f48417b2f3 100644
--- a/app-cdr/xfburn/ChangeLog
+++ b/app-cdr/xfburn/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-cdr/xfburn
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/xfburn/ChangeLog,v 1.44 2012/05/31 03:09:08 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/xfburn/ChangeLog,v 1.45 2012/05/31 21:26:16 ssuominen Exp $
+
+*xfburn-0.4.3_p20120601 (31 May 2012)
+
+  31 May 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +xfburn-0.4.3_p20120601.ebuild:
+  Use latest from git which should be reasonable stable.
 
   31 May 2012; Zac Medico <zmedico@gentoo.org> xfburn-0.4.3-r3.ebuild:
   inherit eutils for epatch
diff --git a/app-cdr/xfburn/xfburn-0.4.3_p20120601.ebuild b/app-cdr/xfburn/xfburn-0.4.3_p20120601.ebuild
new file mode 100644
index 000000000000..6be142b1b6f7
--- /dev/null
+++ b/app-cdr/xfburn/xfburn-0.4.3_p20120601.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/xfburn/xfburn-0.4.3_p20120601.ebuild,v 1.1 2012/05/31 21:26:16 ssuominen Exp $
+
+EAPI=4
+EAUTORECONF=yes
+inherit xfconf
+
+DESCRIPTION="GTK+ based CD and DVD burning application"
+HOMEPAGE="http://goodies.xfce.org/projects/applications/xfburn"
+SRC_URI="http://dev.gentoo.org/~ssuominen/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug gstreamer udev"
+
+RDEPEND=">=dev-libs/glib-2.30
+	>=dev-libs/libburn-0.4.2
+	>=dev-libs/libisofs-0.6.2
+	>=x11-libs/gtk+-2.24:2
+	>=xfce-base/exo-0.6
+	>=xfce-base/libxfce4ui-4.8
+	gstreamer? ( >=media-libs/gst-plugins-base-0.10.20:0.10 )
+	udev? ( || ( >=sys-fs/udev-171-r6[gudev] <sys-fs/udev-171[extras] ) )"
+# dev-libs/libxslt -> xsltproc -> --enable-maintainer-mode -> docs/Makefile.am
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	PATCHES=(
+		"${FILESDIR}"/${PN}-0.4.3-empty_directory_segmentation_fault-2.patch
+		)
+
+	XFCONF=(
+		--enable-maintainer-mode
+		$(use_enable udev gudev)
+		$(use_enable gstreamer)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS ChangeLog NEWS README TODO )
+}
+
+src_prepare() {
+	# http://bugzilla.xfce.org/show_bug.cgi?id=8976
+	sed -i -e 's:BM_DEBUG_SUPPORT:XDT_FEATURE_DEBUG:' configure.in.in || die
+
+	# .in.in -> .in
+	sed -i -e '/^exec.*xdt-autogen/d' autogen.sh || die
+	./autogen.sh
+
+	xfconf_src_prepare
+}