Version bump.

(Portage version: 2.2.0_alpha99/cvs/Linux x86_64)

2 files changed, 90 insertions, 1 deletions

diff --git a/app-arch/libarchive/ChangeLog b/app-arch/libarchive/ChangeLog
index b234228839a7..36ebf758ad9d 100644
--- a/app-arch/libarchive/ChangeLog
+++ b/app-arch/libarchive/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/libarchive
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.120 2012/03/22 07:53:06 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.121 2012/04/07 21:07:04 ssuominen Exp $
+
+*libarchive-3.0.4 (07 Apr 2012)
+
+  07 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +libarchive-3.0.4.ebuild:
+  Version bump.
 
   22 Mar 2012; Samuli Suominen <ssuominen@gentoo.org> metadata.xml:
   Maintained now by ferringb@, me, and bsd@ (in this order)
diff --git a/app-arch/libarchive/libarchive-3.0.4.ebuild b/app-arch/libarchive/libarchive-3.0.4.ebuild
new file mode 100644
index 000000000000..1b5b49ad24a5
--- /dev/null
+++ b/app-arch/libarchive/libarchive-3.0.4.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-3.0.4.ebuild,v 1.1 2012/04/07 21:07:04 ssuominen Exp $
+
+EAPI=4
+inherit eutils multilib
+
+DESCRIPTION="BSD tar command"
+HOMEPAGE="http://libarchive.github.com/"
+SRC_URI="mirror://github/${PN}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="acl +bzip2 +e2fsprogs expat +iconv kernel_linux +lzma nettle static-libs xattr +zlib"
+
+RDEPEND="dev-libs/openssl:0
+	acl? ( virtual/acl )
+	bzip2? ( app-arch/bzip2 )
+	expat? ( dev-libs/expat )
+	!expat? ( dev-libs/libxml2 )
+	iconv? ( virtual/libiconv )
+	kernel_linux? (
+		xattr? ( sys-apps/attr )
+		)
+	lzma? ( app-arch/xz-utils )
+	nettle? ( dev-libs/nettle )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	kernel_linux? (
+		virtual/os-headers
+		e2fsprogs? ( sys-fs/e2fsprogs )
+		)"
+
+DOCS="NEWS README"
+
+src_configure() {
+	export ac_cv_header_ext2fs_ext2_fs_h=$(usex e2fsprogs) #354923
+
+	# We disable lzmadec because we support the newer liblzma from xz-utils
+	# and not liblzmadec with this version.
+	econf \
+		$(use_enable static-libs static) \
+		--enable-bsdtar=shared \
+		--enable-bsdcpio=shared \
+		$(use_enable xattr) \
+		$(use_enable acl) \
+		$(use_with zlib) \
+		$(use_with bzip2 bz2lib) \
+		--without-lzmadec \
+		$(use_with iconv) \
+		$(use_with lzma) \
+		$(use_with nettle) \
+		$(use_with !expat xml2) \
+		$(use_with expat)
+}
+
+src_test() {
+	# Replace the default src_test so that it builds tests in parallel
+	emake check
+}
+
+src_install() {
+	default
+
+	# Libs.private: should be used from libarchive.pc instead
+	rm -f "${ED}"usr/lib*/lib*.la
+
+	# Create tar symlink for FreeBSD
+	if [[ ${CHOST} == *-freebsd* ]]; then
+		dosym bsdtar /usr/bin/tar
+		echo '.so bsdtar.1' > "${T}"/tar.1
+		doman "${T}"/tar.1
+		# We may wish to switch to symlink bsdcpio to cpio too one day
+	fi
+}
+
+pkg_preinst() {
+	preserve_old_lib /{,usr/}$(get_libdir)/${PN}$(get_libname 2)
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /{,usr/}$(get_libdir)/${PN}$(get_libname 2)
+}