Version bump.

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

3 files changed, 95 insertions, 3 deletions

diff --git a/app-arch/libarchive/ChangeLog b/app-arch/libarchive/ChangeLog
index fed2ceb283f3..299ee7c0453a 100644
--- a/app-arch/libarchive/ChangeLog
+++ b/app-arch/libarchive/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/libarchive
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.97 2011/10/29 18:41:18 armin76 Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.98 2012/01/10 12:52:25 ssuominen Exp $
+
+*libarchive-3.0.2 (10 Jan 2012)
+
+  10 Jan 2012; Samuli Suominen <ssuominen@gentoo.org> +libarchive-3.0.2.ebuild,
+  metadata.xml:
+  Version bump. Remove USE="static" and move everything back to /usr wrt #398047
+  by Michał Górny.
 
   29 Oct 2011; Raúl Porcel <armin76@gentoo.org> libarchive-2.8.4-r1.ebuild:
   s390 stable
diff --git a/app-arch/libarchive/libarchive-3.0.2.ebuild b/app-arch/libarchive/libarchive-3.0.2.ebuild
new file mode 100644
index 000000000000..9dc659ebc6f3
--- /dev/null
+++ b/app-arch/libarchive/libarchive-3.0.2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-3.0.2.ebuild,v 1.1 2012/01/10 12:52:25 ssuominen Exp $
+
+EAPI=4
+inherit eutils multilib
+
+DESCRIPTION="BSD tar command"
+HOMEPAGE="http://code.google.com/p/libarchive/"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="acl +bzip2 expat +iconv kernel_linux +lzma nettle static-libs xattr +zlib"
+
+RDEPEND="!dev-libs/libarchive
+	dev-libs/openssl:0
+	acl? ( virtual/acl )
+	bzip2? ( app-arch/bzip2 )
+	expat? ( dev-libs/expat )
+	!expat? ( dev-libs/libxml2 )
+	iconv? ( virtual/libiconv )
+	lzma? ( app-arch/xz-utils )
+	nettle? ( dev-libs/nettle )
+	xattr? (
+		kernel_linux? ( sys-apps/attr )
+		)
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	kernel_linux? (
+		sys-fs/e2fsprogs
+		virtual/os-headers
+		)"
+
+src_configure() {
+	# We disable lzmadec because we support the newer liblzma from xz-utils
+	# and not liblzmadec with this version.
+	econf \
+		$(use_enable static-libs static) \
+		--enable-bsdtar=shared \
+		--enable-bsdcpio=shared \
+		$(use_enable xattr) \
+		$(use_enable acl) \
+		$(use_with zlib) \
+		$(use_with bzip2 bz2lib) \
+		--without-lzmadec \
+		$(use_with iconv) \
+		$(use_with lzma) \
+		$(use_with nettle) \
+		$(use_with !expat xml2) \
+		$(use_with expat expat) \
+		${myconf}
+}
+
+src_test() {
+	# Replace the default src_test so that it builds tests in parallel
+	emake check
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	# Libs.private: should be used from libarchive.pc instead
+	rm -f "${ED}"usr/lib*/lib*.la
+
+	# Create tar symlink for FreeBSD
+	if [[ ${CHOST} == *-freebsd* ]]; then
+		dosym bsdtar /usr/bin/tar
+		echo '.so bsdtar.1' > "${T}"/tar.1
+		doman "${T}"/tar.1
+		# We may wish to switch to symlink bsdcpio to cpio too one day
+	fi
+
+	dodoc NEWS README
+}
+
+pkg_preinst() {
+	preserve_old_lib /{,usr/}$(get_libdir)/libarchive$(get_libname 2)
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /{,usr/}$(get_libdir)/libarchive$(get_libname 2)
+}
diff --git a/app-arch/libarchive/metadata.xml b/app-arch/libarchive/metadata.xml
index 5375af28df76..ead8bc8c077e 100644
--- a/app-arch/libarchive/metadata.xml
+++ b/app-arch/libarchive/metadata.xml
@@ -13,7 +13,7 @@
     <flag name="static">
       Build bsdtar and bsdcpio as static archives, removing
       dependencies over the enabled compression libraries (lzma,
-      lzmadec, libbz2, zlib).
+      libbz2, zlib).
     </flag>
     <flag name="zlib">
       Allow accessing gzip-compressed archives through
@@ -28,5 +28,6 @@
       libarchive's native support: bsdtar will keep using bunzip2 as a
       filter if that's not built-in.
     </flag>
+    <flag name="nettle">Use dev-libs/nettle as crypto backend</flag>
   </use>
 </pkgmetadata>