Version bump. Install translated man pages with USE=nls, bug 269905.

(Portage version: 2.2_rc33/cvs/Linux i686)

3 files changed, 97 insertions, 6 deletions

diff --git a/app-admin/realpath/ChangeLog b/app-admin/realpath/ChangeLog
index 36a3e80483c8..9f17b319245f 100644
--- a/app-admin/realpath/ChangeLog
+++ b/app-admin/realpath/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-admin/realpath
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/realpath/ChangeLog,v 1.41 2009/05/19 22:11:35 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/realpath/ChangeLog,v 1.42 2009/06/13 09:37:26 ulm Exp $
+
+*realpath-1.15 (13 Jun 2009)
+
+  13 Jun 2009; Ulrich Mueller <ulm@gentoo.org> realpath-1.14-r1.ebuild,
+  +realpath-1.15.ebuild:
+  Version bump. Install translated man pages (extracted from deb file) with
+  USE=nls again, bug 269905.
 
 *realpath-1.14-r1 (19 May 2009)
 
diff --git a/app-admin/realpath/realpath-1.14-r1.ebuild b/app-admin/realpath/realpath-1.14-r1.ebuild
index 6b5591f40cd9..d0e980fc18a4 100644
--- a/app-admin/realpath/realpath-1.14-r1.ebuild
+++ b/app-admin/realpath/realpath-1.14-r1.ebuild
@@ -1,21 +1,36 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/realpath/realpath-1.14-r1.ebuild,v 1.1 2009/05/19 22:11:35 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/realpath/realpath-1.14-r1.ebuild,v 1.2 2009/06/13 09:37:26 ulm Exp $
 
 EAPI=2
 inherit eutils toolchain-funcs
 
 DESCRIPTION="Return the canonicalized absolute pathname"
 HOMEPAGE="http://packages.debian.org/unstable/utils/realpath"
-SRC_URI="mirror://debian/pool/main/r/${PN}/${PN}_${PV}.tar.gz"
+SRC_URI="mirror://debian/pool/main/r/${PN}/${PN}_${PV}.tar.gz
+	nls? ( mirror://debian/pool/main/r/${PN}/${PN}_${PV}_i386.deb )"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
-IUSE=""
+IUSE="nls"
 
 RDEPEND="!sys-freebsd/freebsd-bin"
 
+src_unpack() {
+	unpack ${PN}_${PV}.tar.gz
+
+	if use nls; then
+		# Unpack the .deb file, in order to get the preprocessed man page
+		# translations. This way we avoid a dependency on app-text/po4a.
+		mkdir deb
+		cd deb
+		unpack ${PN}_${PV}_i386.deb
+		unpack ./data.tar.gz
+		gunzip -r usr/share/man || die "gunzip failed"
+	fi
+}
+
 src_prepare() {
 	epatch "${FILESDIR}"/${P}-build.patch
 	epatch "${FILESDIR}"/${P}-no-po4a.patch
@@ -23,10 +38,21 @@ src_prepare() {
 
 src_compile() {
 	tc-export CC
-	emake VERSION="${PV}"|| die "emake failed"
+	emake VERSION="${PV}" SUBDIRS="src man $(use nls && echo po)" \
+		|| die "emake failed"
 }
 
 src_install() {
-	emake VERSION="${PV}" DESTDIR="${D}" install || die "emake install failed"
+	emake VERSION="${PV}" SUBDIRS="src man $(use nls && echo po)" \
+		DESTDIR="${D}" install || die "emake install failed"
 	newdoc debian/changelog ChangeLog.debian
+
+	if use nls; then
+		local dir
+		for dir in "${WORKDIR}"/deb/usr/share/man/*; do
+			[ -f "${dir}"/man1/realpath.1 ] || continue
+			newman "${dir}"/man1/realpath.1 realpath.${dir##*/}.1 \
+				|| die "newman failed"
+		done
+	fi
 }
diff --git a/app-admin/realpath/realpath-1.15.ebuild b/app-admin/realpath/realpath-1.15.ebuild
new file mode 100644
index 000000000000..26b45aa4a900
--- /dev/null
+++ b/app-admin/realpath/realpath-1.15.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/realpath/realpath-1.15.ebuild,v 1.1 2009/06/13 09:37:26 ulm Exp $
+
+EAPI=2
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Return the canonicalized absolute pathname"
+HOMEPAGE="http://packages.debian.org/unstable/utils/realpath"
+SRC_URI="mirror://debian/pool/main/r/${PN}/${PN}_${PV}.tar.gz
+	nls? ( mirror://debian/pool/main/r/${PN}/${PN}_${PV}_i386.deb )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="nls"
+
+RDEPEND="!sys-freebsd/freebsd-bin"
+
+src_unpack() {
+	unpack ${PN}_${PV}.tar.gz
+
+	if use nls; then
+		# Unpack the .deb file, in order to get the preprocessed man page
+		# translations. This way we avoid a dependency on app-text/po4a.
+		mkdir deb
+		cd deb
+		unpack ${PN}_${PV}_i386.deb
+		unpack ./data.tar.gz
+		gunzip -r usr/share/man || die "gunzip failed"
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.14-build.patch
+	epatch "${FILESDIR}"/${PN}-1.14-no-po4a.patch
+}
+
+src_compile() {
+	tc-export CC
+	emake VERSION="${PV}" SUBDIRS="src man $(use nls && echo po)" \
+		|| die "emake failed"
+}
+
+src_install() {
+	emake VERSION="${PV}" SUBDIRS="src man $(use nls && echo po)" \
+		DESTDIR="${D}" install || die "emake install failed"
+	newdoc debian/changelog ChangeLog.debian
+
+	if use nls; then
+		local dir
+		for dir in "${WORKDIR}"/deb/usr/share/man/*; do
+			[ -f "${dir}"/man1/realpath.1 ] || continue
+			newman "${dir}"/man1/realpath.1 realpath.${dir##*/}.1 \
+				|| die "newman failed"
+		done
+	fi
+}