1 files changed, 46 insertions, 0 deletions
diff --git a/app-arch/archwrap/archwrap-1.22.ebuild b/app-arch/archwrap/archwrap-1.22.ebuild
new file mode 100644
index 00000000..310c3b31
--- /dev/null
+++ b/app-arch/archwrap/archwrap-1.22.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+RESTRICT="mirror"
+inherit eutils
+
+DESCRIPTION="A collection of POSIX shell scripts to invoke archiver programs"
+HOMEPAGE="https://github.com/vaeth/archwrap/"
+SRC_URI="https://github.com/vaeth/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RDEPEND="app-shells/push"
+DEPEND=""
+
+src_prepare() {
+	local i
+	use prefix || for i in bin/*
+	do	test -h "${i}" || sed -i \
+			-e '1s"^#!/usr/bin/env sh$"#!'"${EPREFIX}/bin/sh"'"' \
+			-e 's"^\. archwrap\.sh$". '"${EPREFIX}/usr/share/archwrap/archwrap.sh"'"' \
+			-- "${i}" || die
+	done
+	epatch_user
+}
+
+src_install() {
+	local i
+	insinto /usr/bin
+	for i in bin/*
+	do	if test -h "${i}"
+		then	doins "${i}"
+		elif [ "${i#*/}" != 'archwrap.sh' ]
+		then	dobin "${i}"
+		fi
+	done
+	insinto /usr/share/archwrap
+	doins bin/archwrap.sh
+	insinto /usr/share/zsh/site-functions
+	doins zsh/*
+	dodoc README archwrap_alias
+}