x11-misc/meteo/meteo-0.9.9.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit gnome2-utils meson vala xdg

DESCRIPTION="Forecast application using OpenWeatherMap API"
HOMEPAGE="https://gitlab.com/bitseater/meteo"
SRC_URI="https://gitlab.com/bitseater/meteo/-/archive/${PV}/${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"

DEPEND="
	dev-libs/libappindicator:3
	dev-libs/glib:2
	dev-libs/json-glib
	net-libs/libsoup:2.4
	net-libs/webkit-gtk:4
	x11-libs/gtk+:3
"
RDEPEND="${DEPEND}
	gnome-base/gsettings-desktop-schemas
	x11-themes/hicolor-icon-theme
"
BDEPEND="
	dev-libs/appstream-glib
	dev-util/intltool
	virtual/pkgconfig
"

# One test needs network (#828052), the other simply checks desktop file
# validation, that we also test with our QA tests
RESTRICT="test"

src_prepare() {
	default
	vala_src_prepare
}

src_install() {
	meson_src_install
	dosym com.gitlab.bitseater.meteo /usr/bin/meteo
}

pkg_postinst() {
	xdg_pkg_postinst
	gnome2_schemas_update
}

pkg_postrm() {
	xdg_pkg_postrm
	gnome2_schemas_update
}