blob: 6dba8fb1854ac3a9b4128ee6268aaf78126fd05b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson systemd udev xdg-utils
DESCRIPTION="D-Bus abstraction for enumerating power devices, querying history and statistics"
HOMEPAGE="https://upower.freedesktop.org/"
SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
LICENSE="GPL-2"
SLOT="0/3" # based on SONAME of libupower-glib.so
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
# gtk-doc files are not available as prebuilt in the tarball
IUSE="doc +introspection ios selinux"
DEPEND="
>=dev-libs/glib-2.56:2
sys-apps/dbus:=
introspection? ( dev-libs/gobject-introspection:= )
kernel_linux? (
>=dev-libs/libgudev-236:=
virtual/udev
ios? (
>=app-pda/libimobiledevice-1:=
>=app-pda/libplist-2:=
)
)
"
RDEPEND="${DEPEND}
selinux? ( sec-policy/selinux-devicekit )
"
BDEPEND="
app-text/docbook-xsl-stylesheets
dev-libs/libxslt
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
doc? ( dev-util/gtk-doc )
"
S="${WORKDIR}/${PN}-v${PV}"
QA_MULTILIB_PATHS="usr/lib/${PN}/.*"
PATCHES=(
"${FILESDIR}"/${P}-meson-Don-t-search-for-gtk-doc-if-disabled.patch
)
src_prepare() {
default
xdg_environment_reset
}
src_configure() {
local backend
if use kernel_linux ; then
backend=linux
else
backend=dummy
fi
local emesonargs=(
--localstatedir "${EPREFIX}"/var
-Dman=true
$(meson_use doc gtk-doc)
$(meson_feature introspection)
-Dudevrulesdir="${EPREFIX}$(get_udevdir)/rules.d"
-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
-Dos_backend="${backend}"
$(meson_feature ios idevice)
)
meson_src_configure
}
src_install() {
meson_src_install
keepdir /var/lib/upower #383091
}
pkg_postinst() {
if [[ ${REPLACING_VERSIONS} ]] && ver_test ${REPLACING_VERSIONS} -lt 0.99.12; then
elog "Support for Logitech Unifying Receiver battery state readout was"
elog "removed in version 0.99.12, these devices have been directly"
elog "supported by the Linux kernel since version >=3.2."
elog
elog "Support for CSR devices battery state was removed from udev rules"
elog "in version 0.99.12. This concerns the following Logitech products"
elog "from the mid 2000s:"
elog "Mouse/Dual/Keyboard+Mouse Receiver, Freedom Optical, Elite Duo,"
elog "MX700/MX1000, Optical TrackMan, Click! Mouse, Presenter."
fi
}
|
GitWeb