blob: e69821e41d3169b11a03090d6fd04a91915996d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit meson-multilib python-any-r1
DESCRIPTION="C library for the Public Suffix List"
HOMEPAGE="https://github.com/rockdaboot/libpsl"
SRC_URI="https://github.com/rockdaboot/${PN}/releases/download/${PV}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="icu +idn test"
RESTRICT="!test? ( test )"
RDEPEND="
icu? ( !idn? ( dev-libs/icu:=[${MULTILIB_USEDEP}] ) )
idn? (
dev-libs/libunistring:=[${MULTILIB_USEDEP}]
net-dns/libidn2:=[${MULTILIB_USEDEP}]
)
"
DEPEND="${RDEPEND}"
BDEPEND="
${PYTHON_DEPS}
sys-devel/gettext
virtual/pkgconfig
"
pkg_pretend() {
if use icu && use idn ; then
ewarn "\"icu\" and \"idn\" USE flags are enabled. Using \"idn\"."
fi
}
multilib_src_configure() {
local emesonargs=(
$(meson_use test tests)
)
# Prefer idn even if icu is in USE as well
if use idn ; then
emesonargs+=(
-Druntime=libidn2
-Dbuiltin=true
)
elif use icu ; then
emesonargs+=(
-Druntime=libicu
-Dbuiltin=true
)
else
emesonargs+=(
-Druntime=no
)
fi
meson_src_configure
}
|
GitWeb
