blob: 49e48df4376563c57f7c9f31c8f6730573327610 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/netfilter.org.asc
inherit linux-info usr-ldscript verify-sig
DESCRIPTION="Netlink API to the in-kernel nf_tables subsystem"
HOMEPAGE="https://netfilter.org/projects/nftables/"
if [[ ${PV} =~ ^[9]{4,}$ ]]; then
inherit autotools git-r3
EGIT_REPO_URI="https://git.netfilter.org/${PN}"
else
SRC_URI="https://netfilter.org/projects/${PN}/files/${P}.tar.bz2
verify-sig? ( https://netfilter.org/projects/${PN}/files/${P}.tar.bz2.sig )"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
BDEPEND+="verify-sig? ( sec-keys/openpgp-keys-netfilter )"
fi
LICENSE="GPL-2"
SLOT="0/11" # libnftnl.so version
IUSE="examples static-libs test"
RESTRICT="!test? ( test )"
RDEPEND=">=net-libs/libmnl-1.0.4:="
BDEPEND+=" virtual/pkgconfig"
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}"/${P}-missing-export-set_elem.patch
)
pkg_setup() {
if kernel_is ge 3 13; then
CONFIG_CHECK="~NF_TABLES"
linux-info_pkg_setup
else
eerror "This package requires kernel version 3.13 or newer to work properly."
fi
}
src_prepare() {
default
[[ ${PV} =~ ^[9]{4,}$ ]] && eautoreconf
}
src_configure() {
local myeconfargs=(
$(use_enable static-libs static)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
gen_usr_ldscript -a nftnl
find "${ED}" -type f -name '*.la' -delete || die
if use examples; then
find examples/ -name 'Makefile*' -delete || die "Could not rm examples"
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
}
|
GitWeb
