blob: 17031a42b832c5febb73a98cb2e7e19c28095662 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic multilib-minimal toolchain-funcs
DESCRIPTION="Lossy speech compression library and tool"
HOMEPAGE="https://packages.qa.debian.org/libg/libgsm.html"
SRC_URI="mirror://gentoo/${P}.tar.gz"
LICENSE="gsm"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86"
S="${WORKDIR}/${PN}-$(ver_rs 2 '-pl' )"
PATCHES=(
"${FILESDIR}"/${P}-shared.patch
"${FILESDIR}"/${PN}-1.0.12-memcpy.patch
"${FILESDIR}"/${PN}-1.0.12-64bit.patch
)
DOCS=( ChangeLog MACHINES MANIFEST README )
src_prepare() {
default
sed -e 's/\$(GSM_INSTALL_LIB)\/libgsm.a //g' -i Makefile || die
multilib_copy_sources
}
src_configure() {
# From upstream Makefile. Define this if your host multiplies
# floats faster than integers, e.g. on a SPARCstation.
use sparc && append-flags -DUSE_FLOAT_MUL -DFAST
}
multilib_src_compile() {
emake -j1 CCFLAGS="${CFLAGS} -c -DNeedFunctionPrototypes=1" \
LD="$(tc-getCC)" AR="$(tc-getAR)" CC="$(tc-getCC)" RANLIB="$(tc-getRANLIB)"
}
multilib_src_install() {
dodir /usr/bin /usr/$(get_libdir) /usr/include/gsm /usr/share/man/man{1,3}
emake -j1 INSTALL_ROOT="${ED}"/usr \
LD="$(tc-getCC)" AR="$(tc-getAR)" CC="$(tc-getCC)" RANLIB="$(tc-getRANLIB)" \
GSM_INSTALL_LIB="${ED}"/usr/$(get_libdir) \
GSM_INSTALL_INC="${ED}"/usr/include/gsm \
GSM_INSTALL_MAN="${ED}"/usr/share/man/man3 \
TOAST_INSTALL_MAN="${ED}"/usr/share/man/man1 \
install
dolib.so lib/libgsm.so*
dosym ../gsm/gsm.h /usr/include/libgsm/gsm.h
}
|
GitWeb
