blob: edeebb7b82a14cb48a5da07a0ef81e0569dad83d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools desktop
DESCRIPTION="Game about an evil hacker called Bill!"
HOMEPAGE="http://www.xbill.org/"
SRC_URI="
http://www.xbill.org/download/${P}.tar.gz
https://dashboard.snapcraft.io/site_media/appmedia/2018/04/xbill.png"
LICENSE="GPL-1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~x86"
RDEPEND="
acct-group/gamestat
media-fonts/font-misc-misc
x11-libs/libXaw"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${P}-gentoo.patch
"${FILESDIR}"/${P}-clang16.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
local econfargs=(
--disable-motif
--disable-gtk
--enable-athena
)
econf "${econfargs[@]}"
}
src_install() {
default
doicon "${DISTDIR}"/${PN}.png
make_desktop_entry ${PN} XBill ${PN}
fowners :gamestat /var/lib/xbill/scores /usr/bin/${PN}
fperms 664 /var/lib/xbill/scores
}
|
GitWeb
