blob: bc33c8cfb4db81feb649079ca7103105734521c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
inherit eutils udev
DESCRIPTION="Library to handle input devices in Wayland"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/"
SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
LICENSE="MIT"
SLOT="0/10"
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86"
IUSE="input_devices_wacom test"
# Tests require write access to udev rules directory which is a no-no for live system.
# Other tests are just about logs, exported symbols and autotest of the test library.
RESTRICT="test"
RDEPEND="
input_devices_wacom? ( >=dev-libs/libwacom-0.12 )
>=dev-libs/libevdev-0.4
>=sys-libs/mtdev-1.1
virtual/libudev
"
DEPEND="${RDEPEND}
virtual/pkgconfig"
# test? (
# >=dev-libs/check-0.9.10
# dev-util/valgrind
# sys-libs/libunwind )
src_prepare() {
# Doc handling in kinda strange but everything
# is available in the tarball already.
sed -e 's/^\(SUBDIRS =.*\)doc\(.*\)$/\1\2/' \
-i Makefile.am Makefile.in || die
}
src_configure() {
# gui can be built but will not be installed
# building documentation silently fails with graphviz syntax errors
econf \
--disable-documentation \
--disable-event-gui \
$(use_enable input_devices_wacom libwacom) \
$(use_enable test tests) \
--with-udev-dir="$(get_udevdir)"
}
src_install() {
emake install DESTDIR="${D}"
dodoc -r doc/html
prune_libtool_files
}
|
GitWeb
