blob: 0b2e45036a1b429b24aff12b6e986ab5196dd713 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# ebuild generated by hackport 0.8.2.0.9999
#hackport: flags: +small_base
CABAL_FEATURES="test-suite"
inherit haskell-cabal
DESCRIPTION="Alex is a tool for generating lexical analysers in Haskell"
HOMEPAGE="https://www.haskell.org/alex/"
GIT_REPO="https://github.com/haskell/${PN}"
GIT_COMMIT="13732056ff8d287f2ee0c4ecb968efe04516c890"
GIT_P="${PN}-${GIT_COMMIT}"
GIT_S="${WORKDIR}/${GIT_P}"
SRC_URI+=" doc? (
${GIT_REPO}/archive/${GIT_COMMIT}.tar.gz -> ${GIT_P}.tar.gz
)"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
IUSE="doc"
RDEPEND=">=dev-lang/ghc-8.8.1:=
"
DEPEND="${RDEPEND}
>=dev-haskell/cabal-3.0.0.0
doc? (
dev-python/sphinx
dev-python/sphinx-rtd-theme
)
"
src_prepare() {
if use doc; then
cp -a "${GIT_S}/doc/" "${S}" || die
eapply "${FILESDIR}/${PN}-3.2.7.2-fix-docs.patch"
fi
haskell-cabal_src_prepare
}
src_configure() {
# make sure we don't accidentally use those
# installed in system
haskell-cabal_src_configure \
--with-alex=false \
--with-happy=false \
--flag=small_base
}
src_compile() {
haskell-cabal_src_compile
if use doc; then
emake -C "${S}/doc/" -j1
fi
}
src_test() {
# 1. workaround Setup.hs deadlock: https://github.com/haskell/cabal/issues/2398
# 2. use freshly built ALEX= binary and datadir path
alex_datadir="${S}"/data \
emake -k -C tests all ALEX="${S}"/dist/build/alex/alex
}
src_install() {
haskell-cabal_src_install
if use doc; then
dodoc -r "${S}/doc/_build/html"
fi
}
|
GitWeb
