app-misc/fmawk/fmawk-1.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit optfeature

DESCRIPTION="File manager written in awk"
HOMEPAGE="https://github.com/huijunchen9260/fm.awk/"

if [[ "${PV}" == *9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/huijunchen9260/fm.awk.git"
else
	SRC_URI="https://github.com/huijunchen9260/fm.awk/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
	S="${WORKDIR}/fm.awk-${PV}"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="GPL-3+"
SLOT="0"

RDEPEND="virtual/awk"

src_compile() {
	:
}

src_install() {
	local bin
	for bin in fm.awk fmawk fmawk-previewer; do
		dobin ${bin}
	done

	einstalldocs
}

pkg_postinst() {
	optfeature "PDFs preview" app-text/poppler
	optfeature "images preview" media-gfx/chafa
	optfeature "videos preview" media-video/ffmpegthumbnailer
}