blob: 2735d8fc373e4a551bab0dd3a3a2403a21dc968b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
PYTHON_COMPAT=( python{2_7,3_6} )
inherit distutils-r1 perl-module toolchain-funcs vcs-snapshot
PY_P="python-${PN}-0.2.0_p20141211"
PY_COMMIT="000915e115acac57a1fdbceb1e6361788af83a3d"
DESCRIPTION="Network Kanji code conversion Filter with UTF-8/16 support"
HOMEPAGE="https://ja.osdn.net/projects/nkf/"
SRC_URI="mirror://sourceforge.jp/${PN}/64158/${P}.tar.gz
python? ( https://github.com/fumiyas/python-${PN}/archive/${PY_COMMIT}.tar.gz -> ${PY_P}.tar.gz )"
LICENSE="ZLIB python? ( BSD )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-macos"
IUSE="perl python l10n_ja"
src_prepare() {
sed -i \
-e "/^CFLAGS/{ s/-g -O2//; s/=/+=/; }" \
-e "/ -o ${PN}/s/\(-o \)/\$(LDFLAGS) \1/" \
Makefile
if use python; then
mv "${WORKDIR}"/${PY_P} NKF.python || die
eapply "${FILESDIR}"/${P}-python.patch
fi
default
}
src_configure() {
default
if use perl; then
cd NKF.mod
perl-module_src_configure
cd - >/dev/null
fi
}
src_compile() {
emake CC="$(tc-getCC)"
if use perl; then
cd NKF.mod
perl-module_src_compile
cd - >/dev/null
fi
if use python; then
cd NKF.python
distutils-r1_src_compile
cd - >/dev/null
fi
}
src_test() {
default
if use perl; then
cd NKF.mod
perl-module_src_test
cd - >/dev/null
fi
}
src_install() {
dobin ${PN}
doman ${PN}.1
if use l10n_ja; then
iconv -f ISO-2022-JP-3 -t UTF-8 ${PN}.1j > ${PN}.ja.1 || die
doman ${PN}.ja.1
fi
dodoc ${PN}.doc
if use perl; then
cd NKF.mod
docinto perl
perl-module_src_install
cd - >/dev/null
fi
if use python; then
cd NKF.python
docinto python
DOCS= distutils-r1_src_install
dodoc CHANGES README.md
cd - >/dev/null
fi
}
|
GitWeb